//  Goes and sets off its alarm, if the alarm has not already been set off/destroyed.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
// Cell 4 - Alarm's waypoint
// Cell 5,6 - Alarm's SDF
// Cell 7,8 Alarms (x,y)

begincreaturescript;

variables;

short i,target;
short alerted, finished;

body;

beginstate INIT_STATE;
	alerted = 0;
	finished = 0;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
if (finished == 1) { // Once we've set off the alarm, act normally
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
} else { // If not finished with the alarm...
	if (get_flag(get_memory_cell(5), get_memory_cell(6))) {
		finished = 1;
	} else {
		if (alerted == 0) {
			if (enemies_nearby(8)) {
				// Have a target
				print_named_str(ME, "runs for the alarm.");
				alerted = 1;
			}
		}
		if (alerted) {
			set_state(4);
		}
	}
}

break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate 4; // Running to alarm
	broadcast_terrain_message(1,1);
	if (get_flag(get_memory_cell(5), get_memory_cell(6))) {
		finished = 1;
		set_state(START_STATE);
	} else {
		approach_waypoint(my_number(), get_memory_cell(4) , 1); 
	}
break;


beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;