// Fairly normal, but sometimes uses wand of life drain
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target,charges,victim,victhp,user,healthgap;

body;

beginstate INIT_STATE;
	charges = 3;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	message_dialog("When Kjellka dies, you notice that he dropped a key.","Keys are generally useful things to have, so you take it.");
	change_spec_item(1,1);
	set_flag(5,3,get_flag(5,3) + 1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if ((charges) && (get_health(ME) < (get_max_health(ME) * 2) / 3) && (get_ran(1,1,2) == 1)) {
		user = my_number();
		healthgap = get_max_health(user) - get_health(user);
		i = 0;
		victhp = -1;
		while (i < 4) {
			if (char_ok(i) && (get_health(i) > victhp)) {
				victhp = get_health(i);
				victim = i;
			}
			i = i + 1;
		}

		if (healthgap > get_health(victim)) {
			healthgap = get_health(victim);
		}
		put_jagged_zap(char_loc_x(user),char_loc_y(user),char_loc_x(victim),char_loc_y(victim), 2);
		run_animation_sound(65);
		if (char_has_item_of_class_equip(victim, 1,0)) {
			print_str("Kjellka tries to steal health, but your amulet foils him");
		} else {
			heal_char(user, healthgap);
			print_big_str("Kjellka steals ", healthgap, " hitpoints");
			damage_char(victim, healthgap, 4);
		}
	}
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;