begintownscript;

variables;
short bmessage,marchy,ezra_pound,victim,sbrx,spcx;
short talk;

body;

beginstate 0;

	force_instant_terrain_redraw();
	pause(10);
	reset_dialog();
	add_dialog_str(0,"You walk into the city.  A sign pronounces this city to be Verrat.  Finally, you are walking in Sud Canopy territory.",0);
	add_dialog_str(1,"What you see is nothing more than a small massacre:  Leader's army pierced surgically into the city, killing anyone stupid enough to resist.",0);
	add_dialog_str(2,"Spiegelbrecher went insane, and you certainly cannot trust him anymore, as he now hates you.  He seems fit to destroy anything that he sees.",0);
	add_dialog_str(3,"Leader would do well to know about Spiegelbrecher's mental state.  If Leader knew this, then he would be less likely to make a disastrous tactical blunder.",0);
	add_dialog_str(4,"On the other hand, if Spiegelbrecher is insane and you did not kill him, Leader would be very upset.  Indeed, you didn't even try to strike him.",0);
	add_dialog_str(5,"You could tell Leader nothing; or you could tell Leader that Spiegelbrechedr went rogue and escape, the truth.",0);
	add_dialog_choice(0,"Tell Leader nothing.");
	add_dialog_choice(1,"Tell Leader that Spiegelbrecher is mad.");
	bmessage = run_dialog(1);
	set_flag(99,4,bmessage);

	message_dialog("With your mind made up, you make your way towards the center of town.  You can already see Leader and his generals waiting for you.","");

	set_total_visibility(1);
	force_view_center(24,24);

	marchy = 14;
	while(marchy <= 21){
		march_party(24,marchy);
		force_instant_terrain_redraw();
		pause(5);

		marchy = (marchy + 1);
	}

	reset_dialog();
	if(party_size() > 1)
		add_dialog_str(0,"Leader looks up at you and nods.  _Specialists.  Pleasure seeing you here.  Let's get to business._",0);
	if(party_size() == 1)
		add_dialog_str(0,"Leader looks up at you and nods.  _Specialist.  Pleasure seeing you here.  Let's get to business._",0);
	if(get_flag(99,4) == 1){
		add_dialog_str(1,"You tell Leader that you are ready to follow his orders to the tee.  He shakes his head.  _Yes, I know that much._",0);
		add_dialog_str(2,"_Since we haven't seen any scouts running around as of late, we can take a small reprieve.  Most of the army has camouflaged itself, anyone who comes near this city will be slain._",0);
		if(party_size() > 1)
			add_dialog_str(3,"_Specialists, you can take a well-earned rest._  Suddenly, you see something moving behind leader.",0);
		if(party_size() == 1)
			add_dialog_str(3,"_Specialist, you can take a well-earned rest._  Suddenly, you see something moving behind leader.",0);
	}
	if(get_flag(99,4) == 2){
		add_dialog_str(1,"You tell Leader that Spiegelbrecher went rabid at the Border Guard, but failed to slay him.  Leader's expression suddenly turns into one of rage.",0);
		add_dialog_str(2,"_You incompetent asshats!  Why didn't you tell me this earlier?  I told the army to fortify itself, but Spiegelbrecher could attack us from the rear now.  Your incompetence has jeoparized us all._",0);
		add_dialog_str(3,"_Damn it all.  One of you generals go south and tell the soldiers that they won't have time to rest.  Get them ready to move._  Suddenly, you see something moving behind leader.",0);
	}
	add_dialog_str(4,"Spiegelbrecher.",50);

	bmessage = run_dialog(1);

	marchy = 33;
	while(marchy >= 28){
		relocate_character(19,24,marchy);
		force_instant_terrain_redraw();
		pause(3);

		marchy = (marchy - 1);
	}

	reset_dialog();
	add_dialog_str(0,"_Goddamn, Goddamn, 'tis why I am, Goddamn,_",0);
	add_dialog_str(1,"_So 'gainst the winter's balm._",20);
	add_dialog_str(2,"_Sing goddamm, damm, sing Goddamm._",40);
	add_dialog_str(3,"_Sing goddamm, sing goddamm, DAMM._",60);
	add_dialog_str(4,"Leader turns his head to his rear just as Spiegelbrecher unsheathes his sword.  You try to stop the inevitable, but inevitable it remains as Spiegelbrecher makes a fateful slice.",0);
	add_dialog_choice(0,"...!");
	ezra_pound = run_dialog(1);

	set_terrain(24,27,269);
	set_character_pose(19,1);
	erase_char(18);
	put_boom_on_space(24,27,0,0);
	put_boom_on_space(24,27,0,0);
	force_instant_terrain_redraw();
	run_animation_sound(152);
	pause(5);

	set_character_pose(19,2);
	force_instant_terrain_redraw();
	pause(5);

	victim = 6;
	while(victim <= 17){
		set_character_pose(victim,2);
		set_character_facing(victim,4);

		victim = (victim + 1);
	}
	set_character_facing(1000,4);
	set_character_pose(1000,2);
	force_instant_terrain_redraw();
	play_sound(18);

	set_character_pose(19,1);
	victim = 13;
	while(victim >= 10){
		put_boom_on_space(28,(victim + 13),0,0);
		put_boom_on_space(20,(victim + 13),0,0);
		erase_char(victim);
		erase_char((victim + 4));

		force_instant_terrain_redraw();
		run_animation_sound(152);
		pause(5);

		victim = (victim - 1);
	}

	victim = 6;
	while(victim <= 9){
put_boom_on_space(char_loc_x(victim),char_loc_y(victim),0,0);
		erase_char(victim);

		victim = (victim + 1);
	}
	force_instant_terrain_redraw();
	run_animation_sound(152);
	pause(5);

	set_character_pose(19,0);

	large_draw_pic_dialog(410,"Leader is dead.");

	reset_dialog();
	add_dialog_str(0,"Spiegelbrecher sheathes his sword.  Leader and his generals have just been slain.  You see a glow from behind you.  It is a familiar glow, it is the glow of the Obispopiedra.",0);
	add_dialog_str(1,"_Do not follow me._  He pauses.  _Irony is such a delicious craft element.  I am leaving._",0);
	add_dialog_str(2,"He begins running as quickly as his legs can carry him.  Admittedly, that's pretty fast.",0);
	add_dialog_choice(0,"Follow him!");
	bmessage = run_dialog(1);

	relocate_character(19,25,27);
	set_character_facing(19,7);
	force_instant_terrain_redraw();
	pause(3);

	relocate_character(19,26,26);
	march_party(25,22);
	force_view_center(25,24);
	force_instant_terrain_redraw();
	pause(3);

	relocate_character(19,27,25);
	force_instant_terrain_redraw();
	pause(3);

	relocate_character(19,28,25);
	set_character_facing(19,6);
	march_party(26,23);
	force_view_center(26,24);
	force_instant_terrain_redraw();
	pause(3);

	sbrx = 29;
	spcx = 27;
	while(sbrx < 44){
		relocate_character(19,sbrx,25);
		force_instant_terrain_redraw();
		pause(3);
		sbrx = (sbrx + 1);

		relocate_character(19,sbrx,25);
		march_party(spcx,24);
		force_view_center(spcx,24);
		force_instant_terrain_redraw();
		pause(3);
		sbrx = (sbrx + 1);
		spcx = (spcx + 1);
	}

	erase_char(19);

	while(spcx <= 44){
		march_party(spcx,24);
		force_view_center(spcx,24);
		force_instant_terrain_redraw();
		pause(3);
		spcx = (spcx + 1);
	}

	set_total_visibility(0);
	set_character_pose(1000,0);
	force_instant_terrain_redraw();

	message_dialog("Spiegelbrecher got away very quickly.  He looks to be heading east, and while it may be a long shot, you have to try to put him to justice.","If you are caught by Sud Canopy, you will be executed.  Thus it's imperative that North Canopy's enemies be eliminated here, if only for your own sake.");

break;

beginstate 1;
break;

beginstate START_STATE;
break;

beginstate 11;

	block_entry(1);

break;