// traitor.txt
// Adopted from Kelandon's traitor.txt
// with the addition of calling other monsters with
// the same "group SDF" for cells 4 and 5 to switch
// sides when any of them are killed or damaged.
// Also uses hunter.txt behavior, so the traitor will
// not "hesitate" to attack the party.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - Stuff done flag used to determine whether traitor will
//     switch sides or not.
//   Cell 6 - Flag value for 4,5 needed to make traitor "flip", also
//     the SDF defined by Cell 4,5 is set to this value when the traitor
//     is "called out" without setting the flag.
//   Cell 7 - Attitude to set character to.
//     0 - Friendly
//     1 - Neutral
//     2 - Hostile, A
//     3 - Hostile, B
//   Cell 8 - SDF defined by Cell 4,5 is set to this value when the traitor
//     dies.

begincreaturescript;

variables;

short i,target;
short max,myhp;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);

set_flag(get_memory_cell(4),get_memory_cell(5),get_memory_cell(8));

break;

beginstate START_STATE; 

// TRAITOR STUFF- the important part.

	if(get_flag(get_memory_cell(4),get_memory_cell(5)) >= get_memory_cell(6)){
		if(get_memory_cell(7) == 0){
			set_attitude(my_number(),3);
		}
		if(get_memory_cell(7) == 1){
			set_attitude(my_number(),4);
		}
		if(get_memory_cell(7) == 2){
			set_attitude(my_number(),10);
		}
		if(get_memory_cell(7) >= 3){
			set_attitude(my_number(),11);
		}
	}

// This is to check HP- if the traitor is damaged, it switches.

max = get_max_health(ME);
myhp = get_health(ME);

	if(myhp < max){
		if(get_memory_cell(7) == 0){
			set_attitude(my_number(),3);
		}
		if(get_memory_cell(7) == 1){
			set_attitude(my_number(),4);
		}
		if(get_memory_cell(7) == 2){
			set_attitude(my_number(),10);
		}
		if(get_memory_cell(7) >= 3){
			set_attitude(my_number(),11);
		}
if(get_flag(get_memory_cell(4),get_memory_cell(5)) < get_memory_cell(6)){
set_flag(get_memory_cell(4),get_memory_cell(5),get_memory_cell(6));
}
	}

// Traitor stuff ends here.

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking

// TRAITOR STUFF- the important part.

	if(get_flag(get_memory_cell(4),get_memory_cell(5)) >= get_memory_cell(6)){
		if(get_memory_cell(7) == 0){
			set_attitude(my_number(),3);
		}
		if(get_memory_cell(7) == 1){
			set_attitude(my_number(),4);
		}
		if(get_memory_cell(7) == 2){
			set_attitude(my_number(),10);
		}
		if(get_memory_cell(7) >= 3){
			set_attitude(my_number(),11);
		}
	}

// This is to check HP- if the traitor is damaged, it switches.

max = get_max_health(ME);
myhp = get_health(ME);

	if(myhp < max){
		if(get_memory_cell(7) == 0){
			set_attitude(my_number(),3);
		}
		if(get_memory_cell(7) == 1){
			set_attitude(my_number(),4);
		}
		if(get_memory_cell(7) == 2){
			set_attitude(my_number(),10);
		}
		if(get_memory_cell(7) >= 3){
			set_attitude(my_number(),11);
		}
if(get_flag(get_memory_cell(4),get_memory_cell(5)) < get_memory_cell(6)){
set_flag(get_memory_cell(4),get_memory_cell(5),get_memory_cell(6));
}
	}

// Traitor stuff ends here.

	if (get_attitude(ME) >= 10)
		alert_char(ME);

	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;