// traitor.txt
// Adopted from Kelandon's traitor.txt
// with the addition of calling other monsters with
// the same "group SDF" for cells 4 and 5 to switch
// sides when any of them are killed or damaged.
// Also uses hunter.txt behavior, so the traitor will
// not "hesitate" to attack the party.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - Stuff done flag used to determine whether traitor will
//     switch sides or not.
//   Cell 6 - Flag value for 4,5 needed to make traitor "flip", also
//     the SDF defined by Cell 4,5 is set to this value when the traitor
//     is "called out" without setting the flag.
//   Cell 7 - Attitude to set character to.
//     0 - Friendly
//     1 - Neutral
//     2 - Hostile, A
//     3 - Hostile, B
//   Cell 8 - SDF defined by Cell 4,5 is set to this value when the traitor
//     dies.

begincreaturescript;

variables;

short i,target;
short max,myhp;
short last_abil_time;
short r1;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);

set_flag(get_memory_cell(4),get_memory_cell(5),get_memory_cell(8));

	if(party_size() > 1)
		message_dialog("Fusei is heavily damaged, and seems to be on his last breath.  _Trahison is blind.  He doesn't see it..._","_Specialists, this rebellion is for naught, and I want you to convince Trahison of that as well._");
	if(party_size() == 1)
		message_dialog("Fusei is heavily damaged, and seems to be on his last breath.  _Trahison is blind.  He doesn't see it..._","_Specialist, this rebellion is for naught, and I want you to convince Trahison of that as well._");
	message_dialog("Lieutenant Fusei begins coughing.  With his last act in the world of the living, he reaches a key out of his armor and throws it at you.","What does this mean?  Did Fusei even want to fight you?  At any rate, he's dead now.");
	change_spec_item(25,1);
	award_party_xp(500,40);

break;

beginstate START_STATE; 

// This is to check HP- if the traitor is damaged, it switches.

max = get_max_health(ME);
myhp = get_health(ME);

	if(myhp < max){
		if(get_memory_cell(7) == 0){
			set_attitude(my_number(),3);
		}
		if(get_memory_cell(7) == 1){
			set_attitude(my_number(),4);
		}
		if(get_memory_cell(7) == 2){
			set_attitude(my_number(),10);
		}
		if(get_memory_cell(7) >= 3){
			set_attitude(my_number(),11);
		}
if(get_flag(get_memory_cell(4),get_memory_cell(5)) < get_memory_cell(6)){
set_flag(get_memory_cell(4),get_memory_cell(5),get_memory_cell(6));
}
	}

// Traitor stuff ends here.

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking

	if (get_attitude(ME) >= 10)
		alert_char(ME);

	if (target_ok() == FALSE)
		set_state(START_STATE);

	if ((tick_difference(last_abil_time,get_current_tick()) >= 1) && (get_ran(1,0,1) == 0) && (can_see_char(1000))) {
	  	r1 = get_ran(1,0,2);
	  	if (r1 == 0) {
			print_named_str(ME,"fires a draining beam.");
			put_jagged_zap(my_loc_x(),my_loc_y(),char_loc_x(get_target()),
				char_loc_y(get_target()),3);
			run_animation_sound(46);
			set_char_status(get_target(),1,-10,0,1);
	  		}
	  	if (r1 == 1) {
			print_named_str(ME,"fires a weakening beam.");
			put_jagged_zap(my_loc_x(),my_loc_y(),char_loc_x(get_target()),
				char_loc_y(get_target()),3);
			run_animation_sound(65);
			set_char_status(get_target(),2,-10,0,1);
	  		}
	  	if (r1 == 2) {
			print_named_str(ME,"fires a slowing beam.");
			put_jagged_zap(my_loc_x(),my_loc_y(),char_loc_x(get_target()),
				char_loc_y(get_target()),3);
			run_animation_sound(7);
			set_char_status(get_target(),3,-10,0,1);
	  		}
		last_abil_time = get_current_tick();
		}
	if ((tick_difference(last_abil_time,get_current_tick()) >= 3) && (can_see_char(1000))) {
	  	r1 = get_ran(1,0,2);
	  	if (r1 == 0) {
			print_named_str(ME,"is blessed.");
			put_sparkles_on_char(ME,2,10);
			run_animation_sound(4);
			set_char_status(ME,1,10,0,1);
	  		}
	  	if (r1 == 1) {
			print_named_str(ME,"is shielded.");
			put_sparkles_on_char(ME,4,10);
			run_animation_sound(4);
			set_char_status(ME,2,10,0,1);
	  		}
	  	if (r1 == 2) {
			print_named_str(ME,"speeds up.");
			put_sparkles_on_char(ME,6,10);
			run_animation_sound(12);
			set_char_status(ME,3,10,0,1);
	  		}
		last_abil_time = get_current_tick();
		}

	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;