// Idle Chatter NPC v1.0 (idlechatter.txt)
// by Arenax (ed.ropple@gmail.com)
// Based on Commoner (commoner.txt) by Terror's Martyr (terrorsmartyr@wi.rr.com)
//
//
// Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.  Talks to the party only
// using default responses based on his/her role.
//
// All but Generic characters have speech bubbles that appear, using one
// of five different responses. You may wish to customize these for your
// scenario.
//
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Default response given.
//     0 - Guard
//     1 - Student
//     2 - Trainer
//     3 - Mansion Guard
//     4 - Townsperson
//     5 - Child

begincreaturescript;

variables;

short i,target,rand,prevtalk;

body;

beginstate INIT_STATE;
        if (get_memory_cell(0) == 2)
                set_mobility(ME,0);
        break;

beginstate DEAD_STATE;
        // Set the appropriate stuff done flag for this character being dead
        if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
                set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
        // if I have a target, go find it.
        if (target_ok()) {
                if (dist_to_char(get_target()) <= 16)
                        set_state(3);
                        else set_target(ME,-1);
                }
        
        // Look for a target, attack it if visible
        if (select_target(ME,8,0)) {
                do_attack();
                set_state(3);
                }
                
        // Have I been hit? Strike back!
        if (who_hit_me() >= 0) {
                set_target(ME,who_hit_me());
                do_attack();
                set_state(3);
                }
                
        // Otherwise, just peacefully move around. Go back to start, if I'm too far
        // from where I started.
        if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
                if (get_ran(1,1,100) < 40) 
                        return_to_start(ME,1);
                }
                else if (get_memory_cell(0) == 0) {
                        fidget(ME,25);
                        }

        // if we're in combat and the above didn't give me anything to do, just
        // stop now. Otherwise, game will keep running script, and that eats up CPU time.
        if (am_i_doing_action() == FALSE)
                end_combat_turn();
break;

beginstate 3; // attacking
        if (target_ok() == FALSE)
                set_state(START_STATE);
        do_attack();
break;

beginstate TALKING_STATE;
        rand = get_ran(1,1,5); // Get a random number to select the speech bubble
        if (get_memory_cell(3) == 0) {
                if (rand == 1)
                        create_text_bubble("Watch yourself.");
                if (rand == 2)
                        create_text_bubble("Obey the law!");
                if (rand == 3)
                        create_text_bubble("I wish I was a Specialist.");
                if (rand == 4)
                        create_text_bubble("Praise Leader!");
                if (rand == 5)
                        create_text_bubble("Long Live North Canopy!");
                }
        if (get_memory_cell(3) == 1) {
                if (rand == 1)
                        create_text_bubble("Praise Leader...");
                if (rand == 2)
                        create_text_bubble("I hate school.");
                if (rand == 3)
                        create_text_bubble("Too much work...!");
                if (rand == 4)
                        create_text_bubble("When does this END?");
                if (rand == 5)
                        create_text_bubble("Why are YOU here?");
                }
        if (get_memory_cell(3) == 2) {
                if (rand == 1)
                        create_text_bubble("My students are awful.");
                if (rand == 2)
                        create_text_bubble("When do I get to retire?");
                if (rand == 3)
                        create_text_bubble("Praise Leader!");
                if (rand == 4)
                        create_text_bubble("I don't get paid enough for this.");
                if (rand == 5)
                        create_text_bubble("Maybe I'm too lenient.");
                }
        if (get_memory_cell(3) == 3) {
                if (rand == 1)
                        create_text_bubble("Praise Leader!");
                if (rand == 2)
                        create_text_bubble("This is Leader's mansion.");
                if (rand == 3)
                        create_text_bubble("You are not allowed here.");
                if (rand == 4)
                        create_text_bubble("Go away.");
                if (rand == 5)
                        create_text_bubble("Long live North Canopy!");

                }
        if (get_memory_cell(3) == 4) {
                if (rand == 1)
                        create_text_bubble("Praise Leader.");
                if (rand == 2)
                        create_text_bubble("If you'll excuse me.");
                if (rand == 3)
                        create_text_bubble("Do I know you?");
                if (rand == 4)
                        create_text_bubble("Long live North Canopy.");
                if (rand == 5)
                        create_text_bubble("Go away.");
                }
        if (get_memory_cell(3) == 5) {
                if (rand == 1)
                        create_text_bubble("When can I be Leader?");
                if (rand == 2)
                        create_text_bubble("You look cool!");
                if (rand == 3)
                        create_text_bubble("Mom won't buy me a sword...");
                if (rand == 4)
                        create_text_bubble("Wanna play?");
                if (rand == 5)
                        create_text_bubble("Hi!");

                }
break;