// Idle Chatter NPC v1.0 (idlechatter.txt)
// by Arenax (ed.ropple@gmail.com)
// Based on Commoner (commoner.txt) by Terror's Martyr (terrorsmartyr@wi.rr.com)
//
//
// Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.  Talks to the party only
// using default responses based on his/her role.
//
// All but Generic characters have speech bubbles that appear, using one
// of five different responses. You may wish to customize these for your
// scenario.
//
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Default response given.
//     0 - Guard
//     1 - Bar patron
//     2 - Drunkard

begincreaturescript;

variables;

short i,target,rand,prevtalk;

body;

beginstate INIT_STATE;
        if (get_memory_cell(0) == 2)
                set_mobility(ME,0);
        break;

beginstate DEAD_STATE;
        // Set the appropriate stuff done flag for this character being dead
        if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
                set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
        // if I have a target, go find it.
        if (target_ok()) {
                if (dist_to_char(get_target()) <= 16)
                        set_state(3);
                        else set_target(ME,-1);
                }
        
        // Look for a target, attack it if visible
        if (select_target(ME,8,0)) {
                do_attack();
                set_state(3);
                }
                
        // Have I been hit? Strike back!
        if (who_hit_me() >= 0) {
                set_target(ME,who_hit_me());
                do_attack();
                set_state(3);
                }
                
        // Otherwise, just peacefully move around. Go back to start, if I'm too far
        // from where I started.
        if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
                if (get_ran(1,1,100) < 40) 
                        return_to_start(ME,1);
                }
                else if (get_memory_cell(0) == 0) {
                        fidget(ME,25);
                        }

        // if we're in combat and the above didn't give me anything to do, just
        // stop now. Otherwise, game will keep running script, and that eats up CPU time.
        if (am_i_doing_action() == FALSE)
                end_combat_turn();
break;

beginstate 3; // attacking
        if (target_ok() == FALSE)
                set_state(START_STATE);
        do_attack();
break;

beginstate TALKING_STATE;
        rand = get_ran(1,1,5); // Get a random number to select the speech bubble
        if (get_memory_cell(3) == 0) {
                if (rand == 1)
                        create_text_bubble("Welcome to the Zephirium Inn.");
                if (rand == 2)
			if(party_size() > 1)
                        	create_text_bubble("Enjoy yourselves!");
			if(party_size() == 1)
                        	create_text_bubble("Enjoy yourself!");
                if (rand == 3)
                        create_text_bubble("Remember, no weapons.");
                if (rand == 4)
                        create_text_bubble("Don't bother other patrons.");
                if (rand == 5)
                        create_text_bubble("Please drink responsibly.");
                }
        if (get_memory_cell(3) == 1) {
                if (rand == 1)
                        create_text_bubble("Hey!");
                if (rand == 2)
                        create_text_bubble("How's it going?");
                if (rand == 3)
                        create_text_bubble("Damned good beer.");
                if (rand == 4)
                        create_text_bubble("Wanna buy me some?");
                if (rand == 5)
                        create_text_bubble("I love this place.");
                }
        if (get_memory_cell(3) == 2) {
                if (rand == 1)
                        create_text_bubble("He...  Hello?");
                if (rand == 2)
                        create_text_bubble("*buuuuurp*");
                if (rand == 3)
                        create_text_bubble("More...  Beer...?");
                if (rand == 4)
                        create_text_bubble("You're pretty... *hiccup*");
                if (rand == 5)
                        create_text_bubble("Wh...  Am I alive?");
                }
break;