// OUTDOOR SECTION SCRIPT
//    Section: X = 1, Y = 1: Waterfalls

beginoutdoorscript;

variables;

int choice,dummy;

body;

beginstate INIT_STATE;
// This state called whenever this section is loaded into memory.
break;

beginstate START_STATE;
// Starting state of the section, called every turn the party 
// stands inside this section until you change the state.
break;

beginstate 10;
if (get_flag(221,0) == 0) {
	reset_dialog();
	add_dialog_str(0,"You can hear the roar of waterfalls to the south of you, not just a few, but many. If you go down this way, you'll have to find another way back, since you can't just climb back up the waterfall. You should be sure that you're ready before you go.",0);
	if (get_flag(220,4))
		add_dialog_str(1,"You remember the ghostly slith voice telling you to take the east waterfall.",0);
	set_flag(221,0,run_dialog(1));
	}
break;

beginstate 11;
if (get_flag(221,1) == 0) {
	message_dialog("Whew! That was intense. You've sailed the Waterfall Warren in Avernum, and this is about the same: you're about ready to lose your lunch. You check your belongings to make sure you haven't lost anything, and it looks as though you haven't.","You can see some dry land in the distance, just a short distance away.");
	set_flag(221,1,1);
	}
break;

beginstate 12;
if (get_flag(221,1) == 0) {
	reset_dialog();
	add_dialog_str(0,"Whew! That was intense. You've sailed the Waterfall Warren in Avernum, and this is about the same: you're about ready to lose your lunch. You check your belongings to make sure you haven't lost anything, and it looks as though you haven't.",0);
	if (get_flag(220,4))
		add_dialog_str(1,"Suddenly, you hear the same ghostly slice voice as before, calling you from the west. _Come to us,_ it says. _Come to the steady lake._ That sounds pretty appealing right now.",0);
	set_flag(221,1,run_dialog(1));
	}
break;

beginstate 13;
if (get_flag(221,2) == 0) {
	message_dialog("Up ahead you catch your first glimpse of non-slith monsters in these passageways! They are large, blue, reptilian beasts. Unless you miss your mark, you've seen drawings in bestiaries of creature like this; they're called _cryoas._","You've always read that they were mythical, but apparently not. They lumber slowly in front of you as real as life. By all accounts, they are stupid pack animals, and you see nothing to contradict that in front of you.");
	set_flag(221,2,1);
	}
break;

beginstate 14;
if (get_skill_total(16) < 14) {
	message_dialog("You find some strange-looking plants. Unfortunately, you don't know enough about Nature Lore to know what they are or how they might be used.","");
	end();
	}
	
if (get_flag(221,3) == 0) {
	reset_dialog();
	add_dialog_str(0,"You find a patch of Graymold! Your knowledge of Nature Lore extends to how to pick it so that it will keep its vital parts that are useful in potions. Do you wish to pick it?",0);
	add_dialog_choice(0,"No. (Leave it alone.)");
	add_dialog_choice(1,"Yes. (Pick it.)");
	if (run_dialog(1) == 2) {
		set_flag(221,3,reward_give(217));
		}
	}
else
	message_dialog("Graymold grows back slowly, and this patch has not yet grown back.","");
break;