// OUTDOOR SECTION SCRIPT
//    Section: X = 0, Y = 0: Near Vasskolis

beginoutdoorscript;

variables;

int choice,dummy;

body;

beginstate INIT_STATE;
// This state called whenever this section is loaded into memory.
break;

beginstate START_STATE;
// Starting state of the section, called every turn the party 
// stands inside this section until you change the state.
if (get_flag(3,0) != 0)
	eliminate_outdoor_enc(3,0);
break;


beginstate 10;
	reset_dialog();
	add_dialog_str(0,"This way leads back up to Avernum. Would you like to leave behind Legare and his expedition, ending your time here?",0);
	add_dialog_choice(0,"No. (Turn back towards Vasskolis.)");
	add_dialog_choice(1,"Yes. (Leave to Avernum.)");
	if (run_dialog(1) == 1)
		block_entry(1);
	else
		end_scenario(0);
break;

beginstate 11;
	block_entry(1);
	message_dialog("Back this way is Mount Galthrax, the home of the late dragon Galthrax, who you slayed. Some of his creations and servants are still there, and they probably wouldn't be very friendly to you, so you turn back, opting not to take your chances there.","");
break;

beginstate 12;
	block_entry(1);
	message_dialog("It's probably not a good idea to get too close to the west bank of the river, just in case any of the sliths of Gnass are left. You don't want a fight with them.","");
break;

beginstate 13;
if (get_flag(200,0) == 0) {
	set_flag(200,0,1);
	message_dialog("You come to an apparent dead end. Looking closer, you realize that there is a very small hole in the wall here. You never would've seen it if your attention hadn't been directed to it by this passage, but now that you've seen it, you can pass through.","");
	}
break;

beginstate 14;
if (get_flag(200,0) == 0) 
	block_entry(1);
break;

beginstate 15;
if (get_flag(200,0) == 0)
	end();

if (has_item(483) == 0)
	message_dialog("You've reached the west shore of the river, so close to camp that you can see it. However, you have no way of crossing. You scan the opposite shore to see if anyone is there who can help you, but no one is in sight.","It looks as though you're stuck unless you can find some way to cross. You may have to retrace your steps.");
	else {
	if (get_flag(200,1) == 0) {
		set_flag(200,1,1);
		message_dialog("You've reached the west shore of the river, so close to camp that you can see it. You're almost back!","");
		}
	}
break;

beginstate 16;
if (get_flag(200,0) == 1)
	set_flag(200,2,5);
break;

beginstate 17;
if (get_flag(200,3) == 0) {
	set_flag(200,3,1);
	message_dialog("You set off south down the river, about to journey deeper into the slith homeland than any outsider has ever gone. Not far away is a city!","To your dismay, though, you notice that the city is ruined. It was destroyed some time ago. You can only hope that the rest of the homeland is not like this.");
	}
break;