// Cloud Killer v1.0
// cloudkill.txt
// by Kelandon (tomwatts@berkeley.edu), based on basicnpc by Jeff Vogel
//
// Like Exodus's BasicNPC, but casts the special spell Cloudkill.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - Which town state to call when dead. If left at 0, none.
//	 Cell 2 - Distractibility factor. This number minus one times ten is the
//		percent chance of a creature getting distracted from its current target
//		and attacking the most recent thing that hit it. If left at 0, this
//		defaults to 4, which gives a 30% chance. (If set to 1, it has a 0%
//		chance, and if set to 11, it has a 100% chance.)
//   Cell 3 - Dialogue node to start with if talked to. If left at 0, this
//     character doesn't talk.
//   Cell 4 - If not talking, chooses the message to use.
//	 Cell 5 - Level of the Cloudkill spell. If left at 0, defaults to 2.

begincreaturescript;

variables;

short i,j,target,last_abil_time;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);

	if (get_memory_cell(2) == 0)
		set_memory_cell(2,4);
	if (get_memory_cell(5) == 0)
		set_memory_cell(5,2);
		
	last_abil_time = get_current_tick();
break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	
	if (get_ran(1,1,3) == 1)
		set_state_continue(10);
	
	// Distractibility.
	if (who_hit_me() >= 0)
		if (get_ran(1,1,10) < get_memory_cell(2))
			set_target(my_number(),who_hit_me());
	
	if (tick_difference(last_abil_time,get_current_tick()) >= 2) {	
		print_named_str(my_number(),"casts Cloudkill!");
		put_jagged_zap(char_loc_x(my_number()),char_loc_y(my_number()),char_loc_x(get_target()),char_loc_y(get_target()),2);
		put_effect_on_char(get_target(),5,1,2);
		run_animation_sound(25);
		i = 0;
		while (i < 120) {
			set_flag(296 + (i / 30),i % 30,get_char_status(i,4));
			set_char_status(i,4,0 - get_char_status(i,4),1,0);
			i = i + 1;
			}
		set_char_status(my_number(),4,1,1,0);
		damage_near_loc(char_loc_x(get_target()),char_loc_y(get_target()),get_ran(7,1,15) + (get_ran(11,1,23) * get_memory_cell(5)) + ((get_stat(my_number(),2) + get_stat(my_number(),11) + get_stat(my_number(),25)) * 7),3,4);
		set_char_status(my_number(),4,-1,1,0);
		i = 0;
		while (i < 120) {
			set_char_status(i,4,get_flag(296 + (i / 30),i % 30),1,0);
			i = i + 1;
			}
		last_abil_time = get_current_tick();
		}
			
	do_attack();
break;

beginstate 10; // targeting -- tries to get something far away
	if (dist_to_char(get_target()) > 3)
		set_state_continue(3);
	if (select_target(ME,8,1))
		if (dist_to_char(get_target()) > 3)
			set_state_continue(3);
	
	j = 120;
	i = 0;
	while (i <= 119) {
		if (can_see_char(i))
			if (char_attitude_to_char(my_number(),i) == 2)
				if (dist_to_char(get_target()) > 3)
					if (get_stat(i,11) > get_stat(get_target(),11))
						set_target(my_number(),i);
		i = i + 1;
		}
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		if (get_memory_cell(4) == 0)
			print_str("Talking: It doesn't respond.");
		if (get_memory_cell(4) == 1)
			print_str("Talking: The ghost drifts aimlessly by.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;