// Zapper v1.0.1
// zapper.txt
// by Kelandon (tomwatts@berkeley.edu)
//
// Much like Exodus's BasicNPC, but has a special ability when attacking. It 
// zaps, which does damage to the target.
//
// New version incorporates distractibility and different damage types, and it
// handles Special Death capability better. Also can animate or not.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - Which town state to call when the creature dies. If left at 0,
//		none.
//	 Cell 2 - Distractibility factor. This number minus one times ten is the
//		percent chance of a creature getting distracted from its current target
//		and attacking the most recent thing that hit it. If left at 0, this
//		defaults to 4, which gives a 30% chance. (If set to 1, it has a 0%
//		chance, and if set to 11, it has a 100% chance.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 4,5 - Amount of damage to do when zapping. Will be a random amount
//		between these two numbers. If cell 5 is 0, it will default to 10.
//	 Cell 6 - Number of ticks to elapse between possible zaps. If 0, can zap
//		every turn.
//	 Cell 7 - Fraction of the probability of a zap. (So if this is 3, the
//		creature has a 1/3 chance of zapping when the turn comes around. If this
//		is not set to 1, cell 6 is probably best left at 0. If this cell is left
//		at 0, it defaults to 1.
//	 Cell 8 - Kind of damage to do when zapping. From the docs:
//		0 - weapon
//		1 - fire
//		2 - poison
//		3 - general magic
//		4 - unblockable
//		5 - cold
//		6 Ð acid
//	 Cell 9 - Whether to animate the zap or not. If 0, yes. If 1, no.

begincreaturescript;

variables;

short i,j,target,do_zap,last_abil_time;
string dlgstr;

body;

beginstate INIT_STATE;
	if (get_memory_cell(7) == 0)
		set_memory_cell(7,1);
	if (get_memory_cell(5) == 0)
		set_memory_cell(5,10);
	if (get_memory_cell(5) < get_memory_cell(4)) {
		i = get_memory_cell(5);
		j = get_memory_cell(4);
		set_memory_cell(4,i);
		set_memory_cell(5,j);
		}
		
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	
	last_abil_time = get_current_tick();
break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		if (select_target(ME,12,0) == 0)
			set_state_continue(START_STATE);
	
	// Distractibility.
	if (who_hit_me() >= 0)
		if (get_ran(1,1,10) < get_memory_cell(2))
			set_target(my_number(),who_hit_me());
	
	// Zap.
	if (tick_difference(last_abil_time,get_current_tick()) > get_memory_cell(6))
		do_zap = get_ran(1,1,get_memory_cell(7));
	else
		do_zap = 0;
		
	if (do_zap == 1) {
		i = get_target();
		if (get_memory_cell(9) == 0) {
			put_jagged_zap(my_loc_x(),my_loc_y(),char_loc_x(i),char_loc_y(i),5);
			put_boom_on_char(i,6,0);
			set_character_pose(my_number(),1);
			run_animation_sound(102);
			set_character_pose(my_number(),2);
			force_instant_terrain_redraw();
			}
		clear_buffer();
		append_char_name(my_number());
		append_string(" fires a large ");
		if (get_memory_cell(8) == 0)
			append_string("force");
		if (get_memory_cell(8) == 1)
			append_string("fire");
		if (get_memory_cell(8) == 2)
			append_string("poison");
		if (get_memory_cell(8) == 3)
			append_string("magic");
		if (get_memory_cell(8) == 4)
			append_string("powerful magic");
		if (get_memory_cell(8) == 5)
			append_string("cold");
		if (get_memory_cell(8) == 6)
			append_string("acid");
		append_string(" zap!");
		get_buffer_text(dlgstr);
		print_str(dlgstr);
		damage_char(i,get_ran(1,get_memory_cell(4),get_memory_cell(5)),get_memory_cell(8));
		last_abil_time = get_current_tick();
		}
	
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;