// Status Nearby (Creature) v1.0
// statusnearby2.txt
// by Kelandon (tomwatts@berkeley.edu), based on basicnpc by Jeff Vogel
//
// Like Basicnpc, but causes a status nearby when in combat.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//	 Cell 1 - Which town state to call when dying. If left at 0, none.
//   Cell 2 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 3 - How many turns between causing status. If 0, causes status every
//		turn.
//   Cell 4 - How much of the status.
//   Cell 5 - Radius of status effect.
//   Cell 6 - Which status.
//   Cell 7 - Good_evil_or_all. If 0, only party-friendly creatures get the 
//		status. If 1, only party-hostile ones do. If 2, all creatures do.
//   Cell 8 - Sound to play when causing the status. If left at 0, none.
//	 Cell 9 - Second status to confer. If 0, none. Note that this status is NOT
//		FORCED at the moment, unlike the first one. Resistances apply.

begincreaturescript;

variables;

short i,target,last_abil_time;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	
	last_abil_time = get_current_tick();
break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
		
	if (tick_difference(last_abil_time,get_current_tick()) > get_memory_cell(3)) {
		force_status_nearby(get_memory_cell(4),get_memory_cell(5),get_memory_cell(6),get_memory_cell(7));
		if (get_memory_cell(9) > 0)
			status_nearby(get_memory_cell(4),get_memory_cell(5),get_memory_cell(9),get_memory_cell(7),40);
		if (can_see_char(1000)) {
			set_character_pose(my_number(),1);
			if (get_memory_cell(8) > 0)
				run_animation_sound(get_memory_cell(8));
			else {
				force_instant_terrain_redraw();
				pause(3);
				}
			set_character_pose(my_number(),2);
			force_instant_terrain_redraw();
			}
		last_abil_time = get_current_tick();
		}
		
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(2) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(2));
break;