// Changing Dialogue v1.0.2
// changedialog.txt
// by Kelandon (tomwatts@berkeley.edu)
// Pretty much the same as basicnpc, but talks differently based on a flag. If 
// the flag is non-zero, this character will start at a different talk node.
// 
// New possible function
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. If left at 0, this
//     character doesn't talk.
//	 Cell 4 - Dialogue node to start with if talked to after a flag is set. If
//		left at 0, char will stop talking.
//	 Cell 5,6 - SDF for switching to second dialogue node. If flag not 0, char 
//		will use the node in cell 4, not in cell 3.
//	 Cell 7,8 - Second flag to change dialogue. This flag takes priority, so if
//		the flag from cells 5 and 6 and the flag from these cells are both set,
//		then the node from cell 9 is used. If cells 7 and 8 are both 0, the
//		dialogue won't change.
//	 Cell 9 - The node to start with if the flag in cells 7,8 is set.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if ((get_flag(get_memory_cell(7),get_memory_cell(8)) > 0) && ((get_memory_cell(7)) || (get_memory_cell(8)))) {
		if (get_memory_cell(9) == 0)
			print_str("Talking: It doesn't respond.");
		else
			begin_talk_mode(get_memory_cell(9));
		}
	else {
		if (get_flag(get_memory_cell(5),get_memory_cell(6)) > 0) {
			if (get_memory_cell(4) == 0)
				print_str("Talking: It doesn't respond.");
			else
				begin_talk_mode(get_memory_cell(4));
			end();
			}
		else {
			if (get_memory_cell(3) == 0)
				print_str("Talking: It doesn't respond.");
			else
				begin_talk_mode(get_memory_cell(3));
			}
		}
	
break;