// Death Knell v1.0
// deathknell.txt
// by Kelandon (tomwatts@berkeley.edu), based on basicnpc by Jeff Vogel
//
// Like Exodus's BasicNPC, but uses the special spell Death Knell.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - Which town state to call when dead. If left at 0, none.
//	 Cell 2 - Distractibility factor. This number minus one times ten is the
//		percent chance of a creature getting distracted from its current target
//		and attacking the most recent thing that hit it. If left at 0, this
//		defaults to 4, which gives a 30% chance. (If set to 1, it has a 0%
//		chance, and if set to 11, it has a 100% chance.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 4 - Level at which creature knows the spell Death Knell.

begincreaturescript;

variables;

short i,j,target,last_abil_time;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);

	if (get_memory_cell(2) == 0)
		set_memory_cell(2,4);
		
	last_abil_time = get_current_tick();
break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	
	// Distractibility.
	if (who_hit_me() >= 0)
		if (get_ran(1,1,10) < get_memory_cell(2))
			set_target(my_number(),who_hit_me());
	
	if (tick_difference(last_abil_time,get_current_tick()) >= 2) {	
		i = 0;
		j = 0;
		while (i < 120) {
			if (char_ok(i))
				if (can_see_loc(char_loc_x(i),char_loc_y(i)))
					if (char_attitude_to_char(my_number(),i) == 2) {
						set_flag(296 + (i / 30),i % 30,get_char_status(i,4));
						set_char_status(i,4,0 - get_char_status(i,4),1,0);
						put_boom_on_char(i,3,0);
						run_animation_sound(65);
						damage_char(i,get_ran(9,1,17) + (get_ran(13,1,25) * get_memory_cell(4)) + ((get_stat(my_number(),2) + get_stat(my_number(),11) + get_stat(my_number(),25)) * 8),4);
						set_char_status(i,4,get_flag(296 + (i / 30),i % 30),1,0);
						}
			i = i + 1;
			}
		last_abil_time = get_current_tick();
		}
			
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0)
		print_str("Talking: It doesn't respond.");
	else
		begin_talk_mode(get_memory_cell(3));
break;