// Group-Powered NPC v1.0
// grouppower.txt
// by Kelandon (tomwatts@berkeley.edu), based on groupnpc by Jeff Vogel
//
// Like Exodus's BasicNPC mixed with groupnpc, but powers up the rest of the
// group upon death. When this character dies, the level of the group is
// increased. Note that when this happens, the entire group is fully healed
// also.
//
// Note also that there is no danger involved in setting a creature's level
// above 100, the specified limit. BoA just sets it to 100 instead.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - Which town state to call when dead. If left at 0, none.
//	 Cell 2 - Distractibility factor. This number minus one times ten is the
//		percent chance of a creature getting distracted from its current target
//		and attacking the most recent thing that hit it. If left at 0, this
//		defaults to 4, which gives a 30% chance. (If set to 1, it has a 0%
//		chance, and if set to 11, it has a 100% chance.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - Amount by which to power up the rest of the group when dying. When
//		this character dies, the level of the group is increased by this number.
//		If left at 0, defaults to 3.
//	 Cell 5 - Whether to give update. If 0, gives update. If anything else, does
//		not.
//	 Cell 6 - A status to render while giving level power. If 0, none.
//	 Cell 7 - How much of the status to give. If 0, defaults to 1.
//	 Cell 8 - Which group this is. If 0, it's in Thanopolen.

begincreaturescript;

variables;

short i,j,target;
short i_gave_alert = 0;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);

	if (get_memory_cell(2) == 0)
		set_memory_cell(2,4);
	if (get_memory_cell(4) == 0)
		set_memory_cell(4,3);
	if (get_memory_cell(4) == 0)
		set_memory_cell(7,1);
break;

beginstate DEAD_STATE;
	// Power up other member's of one's group.
	if (get_memory_cell(8) == 0) {
		i = 12;
		j = 40;
		}
	if (get_memory_cell(8) == 1) {
		i = 14;
		j = 21;
		}
	while (i <= j) {
		set_level(i,get_level(my_number()) + get_memory_cell(4));
		if (get_memory_cell(6) > 0)
			set_char_status(i,get_memory_cell(6),get_memory_cell(7),1,0);
		i = i + 1;
		}
	if (get_memory_cell(5) == 0)
		print_str_color("The nearby monsters appear to grow stronger!",2);
	
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE;
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (what_group_in(ME) > 0)
		alert_char(1000 + what_group_in(ME));
		
	if (target_ok() == FALSE)
		set_state(START_STATE);
	
	// Distractibility.
	if (who_hit_me() >= 0)
		if (get_ran(1,1,10) < get_memory_cell(2))
			set_target(my_number(),who_hit_me());
			
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0)
		print_str("Talking: It doesn't respond.");
	else
		begin_talk_mode(get_memory_cell(3));
break;