// Increase Status v1.0
// incstatus.txt
// by Kelandon (tomwatts@berkeley.edu), based on basicnpc by Jeff Vogel
//
// Like Status Nearby (Creature), but confers more and more of the status with 
// each effect.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//	 Cell 1 - Which town state to call when dying. If left at 0, none.
//   Cell 2 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 3 - How many turns between causing status. If 0, causes status every
//		turn.
//   Cell 4 - How much of the status to cause at first.
//   Cell 5 - Radius of status effect.
//   Cell 6 - Which status.
//   Cell 7 - Good_evil_or_all. If 0, only party-friendly creatures get the 
//		status. If 1, only party-hostile ones do. If 2, all creatures do.
//   Cell 8 - Sound to play when causing the status. If left at 0, none.
//	 Cell 9 - Amount to increment status by. If left at 0, defaults to 3.
//
// In other words, if cell 4 is 10 and cell 9 is 5, 10 levels of the status will
// be delivered with the first effect, 15 with the second, 20 with the third,
// and so on.

begincreaturescript;

variables;

short i,target,last_abil_time,times_caused = 0;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
		
	if (get_memory_cell(9) == 0)
		set_memory_cell(9,3);
	
	last_abil_time = get_current_tick();
break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
		
	if (tick_difference(last_abil_time,get_current_tick()) > get_memory_cell(3)) {
		status_nearby(get_memory_cell(4) + (times_caused * get_memory_cell(9)),get_memory_cell(5),get_memory_cell(6),get_memory_cell(7),40);
		if (can_see_char(1000)) {
			set_character_pose(my_number(),1);
			if (get_memory_cell(8) > 0)
				run_animation_sound(get_memory_cell(8));
			else {
				force_instant_terrain_redraw();
				pause(3);
				}
			set_character_pose(my_number(),2);
			force_instant_terrain_redraw();
				}
		times_caused = times_caused + 1;
		last_abil_time = get_current_tick();
		}
		
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(2) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(2));
break;