// OUTDOOR SECTION SCRIPT
//    Section: X = 0, Y = 0: Near Vasskolis

beginoutdoorscript;

variables;

int choice,dummy;

body;

beginstate INIT_STATE;
// This state called whenever this section is loaded into memory.
break;

beginstate START_STATE;
// Starting state of the section, called every turn the party 
// stands inside this section until you change the state.
break;

beginstate 10;
if (get_flag(221,2) == 0) {
	message_dialog("Up ahead you catch your first glimpse of non-slith monsters in these passageways! They are large, blue, reptilian beasts. Unless you miss your mark, you've seen drawings in bestiaries of creature like this; they're called _frost lizards._","You've always read that they were mythical, but apparently not. They lumber slowly in front of you as real as life. By all accounts, they are stupid pack animals, and you see nothing to contradict that in front of you.");
	set_flag(221,2,1);
	}
break;

beginstate 11;
if (get_skill_total(16) < 12) {
	message_dialog("You find some strange-looking plants. Unfortunately, you don't know enough about Nature Lore to know what they are or how they might be used.","");
	end();
	}
	
if (get_flag(222,0) == 0) {
	reset_dialog();
	add_dialog_str(0,"You find a patch of Healing Herbs! Your knowledge of Nature Lore extends to how to pick them so that they will keep their vital parts that are useful in potions. Do you wish to pick them?",0);
	add_dialog_choice(0,"No. (Leave them alone.)");
	add_dialog_choice(1,"Yes. (Pick them.)");
	if (run_dialog(1) == 2) {
		set_flag(222,0,reward_give(214));
		reward_give(214);
		reward_give(214);
		}
	}
else
	message_dialog("Healing Herbs grow back slowly, and these have not yet grown back.","");
break;

beginstate 12;
if (get_skill_total(16) < 13) {
	message_dialog("You find some strange-looking plants. Unfortunately, you don't know enough about Nature Lore to know what they are or how they might be used.","");
	end();
	}
	
if (get_flag(222,1) == 0) {
	reset_dialog();
	add_dialog_str(0,"You find a patch of Spiritual Herbs! Your knowledge of Nature Lore extends to how to pick them so that they will keep their vital parts that are useful in potions. Do you wish to pick them?",0);
	add_dialog_choice(0,"No. (Leave them alone.)");
	add_dialog_choice(1,"Yes. (Pick them.)");
	if (run_dialog(1) == 2) {
		set_flag(222,1,reward_give(215));
		reward_give(215);
		}
	}
else
	message_dialog("Spiritual Herbs grow back slowly, and these have not yet grown back.","");
break;