// Askss v1.0
// t7Askss.txt
// by Kelandon (tomwatts@berkeley.edu), based on basicnpc by Jeff Vogel
//
// Like Exodus's BasicNPC, but heals and summons when hurt.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 4 - Distractibility factor. This number minus one times ten is the
//		percent chance of a creature getting distracted from its current target
//		and attacking the most recent thing that hit it. If left at 0, this
//		defaults to 4, which gives a 30% chance. (If set to 1, it has a 0%
//		chance, and if set to 11, it has a 100% chance.)
//	 Cell 5 - Which hidden group to activate when hurt.
//	 Cell 6,7 - Range of hidden group if appearing with a flash. If left at 0,
//		ignored.
//	 Cell 8 - What kind of flash to use. 2 is a normal "teleport in" one.
//	 Cell 9 - If flashing, what sound to make when appearing. If 0, none.

begincreaturescript;

variables;

short i,target,distract,heal = 0;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);

	distract = get_memory_cell(5);
	if (distract == 0)
		distract = 4;
break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	
	// Distractibility.
	if (who_hit_me() >= 0)
		if (get_ran(1,1,10) < distract)
			set_target(my_number(),who_hit_me());
		
	if (heal == 0)
		if (get_health(my_number()) < get_max_health(my_number()) / 2) {
			message_dialog("Badly wounded, Askss stumbles back and raises his arms. Hissing sibilant words of magic, with a flash, he heals himself and causes several monsters to appear!","");
			change_char_health(my_number(),get_max_health(my_number()) - get_health(my_number()));
			activate_hidden_group(get_memory_cell(5));
			if (get_memory_cell(6) > 0) {
				i = get_memory_cell(6);
				while (i <= get_memory_cell(7)) {
					put_boom_on_char(i,get_memory_cell(8),0);
					i = i + 1;
					}
				if (get_memory_cell(9) > 0)
					run_animation_sound(get_memory_cell(9));
				else
					run_animation();
				}
			heal = 1;
			}
			
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;