// abom.txt
// Two behavior paterns, melee or range.
// Which pattern the creature follows decided via memory cell.
// Script Edited by Lazarus to add some extra features.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - State to call when creature dies.
//   Cell 2 - group to add creature to.
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - range or melee? 1 for range, all else = melee.
//   Cell 9 - What pose to set character to.

begincreaturescript;

variables;

short i,target;
short i_gave_alert;
short alert1,alert2,status,range_melee = 0;
short last_abil_time,namechange;
short last_abil_time2 = get_current_tick - get_ran(1,0,6);

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	if(get_memory_cell(2) > 0)
		add_char_to_group(my_number(),get_memory_cell(2));
	if((get_memory_cell(9) > 0) && (get_memory_cell(9) < 15))
		set_character_pose(ME,get_memory_cell(9));
	if(get_memory_cell(4) == 1)
		range_melee = 1;
	break;

beginstate DEAD_STATE;
	if (get_memory_cell(1) != 0)
		run_town_script(get_memory_cell(1));

	play_sound(-27);
	set_character_pose(ME,11);
	force_instant_terrain_redraw();
	pause(1);
	set_character_pose(ME,12);
	force_instant_terrain_redraw();
	pause(1);
	set_character_pose(ME,13);
	force_instant_terrain_redraw();
	pause(1);
	set_character_pose(ME,14);
	force_instant_terrain_redraw();
	pause(1);

	erase_char(ME);
break;

beginstate START_STATE;
	if(get_flag(15,3) == 1)
		if(namechange == 0){
			namechange = 1;
			set_name(ME,"Disruptor");
		}
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if ((what_group_in(ME) > 0) && (i_gave_alert == 0)) {
		alert_char(1000 + what_group_in(ME));
		i_gave_alert = 1;
		}
	if (target_ok() == FALSE)
		set_state(START_STATE);
if(tick_difference(last_abil_time,get_current_tick()) > 0){
	status = 0;
	alert1 = 0;
	alert2 = 0;
	while(status <= 30){
		if((get_char_status(ME,status) > 0) && (alert2 == 0)){
			print_str_color("Abomination purges statuses!",4);
			alert2 = 1;
			play_sound(65);
			deduct_ap(1);
		}	
		set_char_status(ME,status,-1 * (get_char_status(ME,status)),1,0);
		if((dist_to_char(get_target()) <= 1) && (tick_difference(last_abil_time2,get_current_tick()) > 3)){
			if((get_char_status(get_target(),status) > 0) && (alert1 == 0)){
				print_str_color("Abomination drains all statuses!",4);
				alert1 = 1;
				play_sound(65);
				deduct_ap(4);
				last_abil_time2 = get_current_tick();
			}
			set_char_status(get_target(),status,-1 * (get_char_status(get_target(),status)),1,0);
		}
		status = status + 1;
	}
	last_abil_time = get_current_tick();
}
	if(range_melee == 0)
		do_attack();
	else{
		set_special_ability(ME,17 + get_ran(1,0,1));
		do_attack_tactic(get_ran(1,1,2));
		end_combat_turn();
	}

break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));	
break;