//banshee.txt
//Script by Lazarus
//Creature has "wail" special ability which can be used once per turn. It decreases the PC's strength.
//Max of 2 uses. 25% chance creature will use ability on a given turn.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - What State to call when dead.
//   Cell 2 - What group to add to?
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;
short i_gave_alert = 0;
short last_abil_time = get_current_tick() - get_ran(1,0,2);
short num_augs = 0;

body;

beginstate INIT_STATE;
	i = 0;
	while(char_ok(i) == 0){
		i = i + 1;
	}
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	if(get_memory_cell(2) > 0)
		add_char_to_group(my_number(),get_memory_cell(2));

	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if (get_memory_cell(1) != 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if (my_dist_from_start() >= 6) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if ((what_group_in(ME) > 0) && (i_gave_alert == 0)) {
		alert_char(1000 + what_group_in(ME));
		i_gave_alert = 1;
		}
	if (target_ok() == FALSE)
		set_state(START_STATE);
	if(can_see_char(get_target()) == 0)
		set_state(start_state);
	if ((tick_difference(last_abil_time,get_current_tick()) > 4) && (num_augs <= 1) && (get_ran(1,0,3) == 1) && (get_stat(i,0) > 3)) {
	  	print_str_color("The piercing wail of the banshee strikes fear in your heart.",2);
	  	alter_stat(i,0,-1);
		inc_flag(255,1,1);
	  	num_augs = num_augs + 1;
		last_abil_time = get_current_tick();
		deduct_ap(4);
		set_character_pose(ME,1);
		force_instant_terrain_redraw();
		put_effect_on_char(i,5,5,0);
		run_animation_sound(163);
		damage_char(i,get_ran(1,10,30),3);
		set_character_pose(ME,0);
		force_instant_terrain_redraw();
	  	} 
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;