// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Script Edited by Lazarus to add some extra features.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - State to call when creature dies.
//   Cell 2 - group to add creature to.
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;
short i_gave_alert;
short last_abil_time = get_current_tick() - get_ran(1,0,2);
short xloc,yloc,dest;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	if(get_memory_cell(2) > 0)
		add_char_to_group(my_number(),get_memory_cell(2));
	break;

beginstate DEAD_STATE;
	if (get_memory_cell(1) != 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if ((what_group_in(ME) > 0) && (i_gave_alert == 0)) {
		alert_char(1000 + what_group_in(ME));
		i_gave_alert = 1;
		}
	if (target_ok() == FALSE)
		set_state(START_STATE);
	if((tick_difference(last_abil_time,get_current_tick()) >= 3) && (get_ran(1,0,2) == 0))
		if(num_chars_in_group(4) > 0){
			set_character_pose(ME,1);
			force_instant_terrain_redraw();
			dest = random_group_member(4);
			while(char_ok(dest) == 0){
				dest = random_group_member(4);
			}
			xloc = char_loc_x(dest);
			yloc = char_loc_y(dest);
			erase_char(dest);
			place_monster(xloc,yloc,216,0);
			last_abil_time = get_current_tick();

			put_effect_on_space(xloc,yloc,2,5,0);
			run_animation();
			play_sound(-25);

			put_effect_on_space(xloc,yloc,2,5,1);
			run_animation();

			set_character_pose(ME,0);
			force_instant_terrain_redraw();

			print_str_color("One of the totems begins to glow.",2);
			deduct_ap(4);
		}
		
		
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;