begintownscript;
variables;
short choice;
short i,erase;
short tick1 = 0,tick2 = 0;
short xfall,yfall;

body;
beginstate init_state;
i = 0;
while(char_ok(i) == 0){
	i = i + 1;
}

if(get_flag(2,2) == 2){
	erase = 6;
	while(erase <= 21){
		if(char_ok(erase) == 1)
			erase_char(erase);
		erase = erase + 1;
	}
}
turn_off_training(1);
if(get_flag(2,15) > 0){
	erase_char(41);
	erase_char(50);
	erase_char(55);
	if(get_flag(2,14) == 0)
		activate_hidden_group(7);
}
if((get_flag(3,2) > 0) && (get_flag(4,5) == 0)){
	activate_hidden_group(8);
	activate_hidden_group(9);
	set_terrain(11,12,177);
	set_terrain(10,14,177);
	set_terrain(12,13,177);
	set_terrain(14,15,177);
}
if((get_flag(4,5) > 0) && (get_flag(3,11) == 0)){
	activate_hidden_group(11);
	set_character_pose(66,14);
	put_stain_on_space(9,11,2);
	put_stain_on_space(10,12,1);
	put_stain_on_space(11,14,0);
	set_terrain(11,12,177);
	set_terrain(10,14,177);
	set_terrain(12,13,177);
	set_terrain(14,15,177);
	put_item_on_spot(11,12,463);
}
//Fabian
set_char_dialogue_pic(17,305,0);
set_char_dialogue_pic(27,305,0);
//Jamie
set_char_dialogue_pic(19,306,0);
set_char_dialogue_pic(28,306,0);
//Ainsley
set_char_dialogue_pic(15,1907,0);
//Evrey
set_char_dialogue_pic(21,1957,0);
set_char_dialogue_pic(23,1957,0);
//Erasmus
set_char_dialogue_pic(16,300,0);
set_char_dialogue_pic(25,300,0);
//Orrin
set_char_dialogue_pic(14,304,0);
set_char_dialogue_pic(24,304,0);
//Rowly
set_char_dialogue_pic(20,301,0);
set_char_dialogue_pic(12,301,0);
set_char_dialogue_pic(66,301,0);
//Adrianna
set_char_dialogue_pic(18,1959,0);
set_char_dialogue_pic(22,1959,0);

if(get_flag(3,11) > 0){
	reset_dialog();
	add_dialog_str(0,"You scramble over the top of the snowdrift into the swirling air outside. You look up at the sky but can't tell what time of day it is, you could have slept all night or for a few hours, all you know is it is dark and gloomy.",0);
	add_dialog_str(1,"You pull your hood a bit lower to keep out the wind, and wade through the snow towards your companions.",0);
	add_dialog_str(2,"Sergeant Burden addresses the group, _I-- I'm sorry men. Sorry it ends like this. But we have to go, there's nothing else to be done here. I can't-- have more deaths on my conscience. You must understand._",0);
	add_dialog_str(3,"She trudges away towards the trail leading down, not turning to see if anybody follows. Slowly the rest file in behind her, yourself included.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	set_terrain(8,12,378);
}

break;

beginstate start_state;
if(tick1 > 0)
	tick2 = tick2 + 1;

if((get_flag(2,0) == 1) && (get_flag(2,1) == 0)){
	reset_dialog();
	add_dialog_str(0,"A call from somewhere above you causes everybody in the group's head to turn. You recognize it as Burden's voice even before you see her rounding the corner and coming into view, followed closely by Sir Rowly.",0);
	add_dialog_str(1,"Everybody gets up and shakes the cold from their legs. Meanwhile Burden imparts what she found to Erasmus, you're close enough to hear.",0);
	add_dialog_str(2,"_I didn't see any of the landmarks you told me to look for--_ At this Erasmus begins shaking his head worriedly and mumbles something apologetic, but Burden cuts him off.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);

	reset_dialog();
	add_dialog_str(0,"_But no matter. We saw a cliff face that looked a likely place to make camp. We had to turn back before we could inspect it closer because of some wolves._",0);
	add_dialog_str(1,"At this point Sir Rowly breaks in, _Foolishness, pure foolishness! No wolf will stand up to a man, and for good reason, an armed soldier could...._",0);
	add_dialog_str(2,"Burden cuts him off, _Please Sir Rowly, I told you already why it would be a foolish idea. Erasmus, these wolves were larger and more aggressive than any wolf I've seen. I'd like to navigate around them but-- well given the circumstances we can't._",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);

	reset_dialog();
	add_dialog_str(0,"_It is your decision,_ Erasmus says, _we can handle a group of wolves I think; but it is good that you didn't attack them on your own, we'll go as a group to be cautious._",0);
	add_dialog_str(1,"_Yes, that is my decision._ Burden turns to you and Sir Rowly, _Go tell the men that we're moving out._ Rowly marches away with a pleased look on his face, clearly glad to boss around the others.",0);
	add_dialog_str(2,"You begin to follow, but Burden stops you. _Not you, Vincent. I want to talk to you._ You cross over to speak with she and Erasmus.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);

	reset_dialog();
	add_dialog_str(0,"Sergeant Burden continues in a hushed tone that doesn't carry beyond your and Erasmus' ears, _Vincent, I need somebody to scout ahead and I think you're the best candidate._",0);
	add_dialog_str(1,"_Jamie and Captain Ainsley are obviously of no use here. Orrin is the only one strong enough to help Ainsley, likewise Adrianna and Evrey are out of the question since they are helping Jamie._",0);
	add_dialog_str(2,"_Rowly-- well frankly the man is a loose cannon. I had to almost physically restrain him from charging after those wolves, and I don't trust him to range ahead again._",0);
	add_dialog_str(3,"_I must stay here with him, I don't think he'll listen to anybody else. That leaves you, Fabian, and Erasmus as the only candidates-- with no intention of offending you, Vincent and Fabian are better trained for battle and scouting._",0);
	add_dialog_str(4,"Erasmus nods his head at this last point, which was addressed to him. Burden nods, _I'm glad you understand. Vincent, your assignment is to range ahead and clear a path for us, go tell Fabian and get started._",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	erase = 6;
	while(erase <= 21){
		if(char_ok(erase) == 1)
			erase_char(erase);
		erase = erase + 1;
	}
	activate_hidden_group(2);
//Fabian
set_char_dialogue_pic(27,305,0);
//Jamie
set_char_dialogue_pic(28,306,0);
//Ainsley
set_char_dialogue_pic(29,1907,0);
set_char_dialogue_pic(21,302,0);
set_char_dialogue_pic(23,1957,0);
set_char_dialogue_pic(25,300,0);
set_char_dialogue_pic(26,304,0);
set_char_dialogue_pic(20,301,0);
set_char_dialogue_pic(22,1959,0);
set_char_dialogue_pic(24,303,0);
	set_flag(2,1,1);
}
if((get_flag(2,3) > 0) && (get_flag(2,4) == 0) && (tick1 + 5 < tick2)){
	set_flag(2,4,1);
	activate_hidden_group(4);
	tick1 = 0;
	tick2 = 0;
}
if((num_chars_in_group(1) == 0) && (get_flag(2,4) > 0) && (get_flag(2,5) == 0)){
	set_flag(2,5,1);
	if(get_flag(2,20) == 0)
		message_dialog("Fabian sheathes his sword as the last wolf falls. He surveys the carnage and whistles, _Who ever heard of wolves attacking humans in broad daylight? And look at the size of THIS sucker, the thing is practically a horse!_","He's exaggerating of course, but the wolf in question IS big-- larger than any timber wolf. However, the whole pack is lean to the point of malnourishment. You'd be willing to bet that's why they attacked, but Erasmus could offer a more informed opinion.");
	else
		message_dialog("With the last wolf dead, Fabian is now safe to take up his place at your side again, _Who ever heard of wolves attacking humans in broad daylight? And look at the size of THIS sucker, the thing is practically a horse!_","He's exaggerating of course, but the wolf in question IS big-- larger than any timber wolf. However, the whole pack is lean to the point of malnourishment. You'd be willing to bet that's why they attacked, but Erasmus could offer a more informed opinion.");
	if(get_flag(2,20) > 0)
		set_flag(2,21,1);
}
if((num_chars_in_group(2) == 0) && (get_flag(2,7) > 0) && (get_flag(2,8) == 0)){
	set_flag(2,8,1);
	if(get_flag(2,20) > 0)
		set_flag(2,21,1);
}
if((get_flag(2,11) > 0) && (get_flag(2,12) == 0) && (tick1 + 2 < tick2)){
	set_flag(2,12,1);
	activate_hidden_group(6);
	message_dialog("The noise of your fight has attracted some more starving carnivores. It seems that every wolf for miles around has been attracted here by the prospect of a meal.","");
	tick1 = 0;
	tick2 = 0;
}

if((num_chars_in_group(3) == 0) && (get_flag(2,12) > 0) && (get_flag(2,13) == 0)){
	set_flag(2,13,1);
	if(get_flag(2,20) > 0)
		set_flag(2,21,1);
}
if((is_combat() == 0) && (get_flag(2,21) > 0)){
	activate_hidden_group(10);
	add_char_to_party(54);
	set_flag(2,21,0);
}
break;

beginstate exit_state;
break;

beginstate 10;
if(get_flag(2,2) == 1){
	if(is_combat() > 0)
		block_entry(1);
	else{
		activate_hidden_group(10);
		add_char_to_party(54);
		set_flag(2,2,2);
		move_to_new_town(2,char_loc_x(i),char_loc_y(i));
	}
}

if(get_flag(2,1) == 0){
	block_entry(1);
	message_dialog("The trail ahead leads higher into the mountains. Before you can get far, however, Erasmus' voice halts you. _Vincent, please wait here until Sergeant Burden and Rowly return. Don't go off alone._","");
	end();
}
if(get_flag(2,2) == 0){
	block_entry(1);
	message_dialog("Sergeant Burden's voice stops you before you can get far on the trail leading up into the mountains, _Aren't you forgetting something-- or rather somebody? You were to take Fabian with you, nobody should be wandering alone in the mountains._","");
	end();
}
break;

beginstate 11;
if(get_flag(2,2) == 1){
	if(is_combat() > 0)
		block_entry(1);
	else{
		activate_hidden_group(10);
		add_char_to_party(54);
		set_flag(2,2,2);
		move_to_new_town(2,char_loc_x(i),char_loc_y(i));
	}
}
if(get_flag(2,2) == 0){
	block_entry(1);
	message_dialog("You don't need to be told that straying away from the group is a bad idea. You are unfamiliar with the area and could easily get lost, and if that weren't enough there is a killer animal on the loose. You turn back.","");
}
break;

beginstate 12;
if(get_flag(2,3) == 0){
	set_flag(2,3,1);
	message_dialog("A howl that splits the sunny afternoon air is the only warning you have-- the only thing that affords you the time for you and Fabian to draw your swords before the pack of wolves is upon you.","The wolves lunge down from the steep wall above you and out from the dense forest that surrounds you. You see now why Burden was hesitant to approach these animals.");
	activate_hidden_group(3);
	if(get_flag(2,20) > 0)
		erase_char(4);
	tick1 = 1;
}
break;

beginstate 13;
if(get_flag(2,6) == 0){
	reset_dialog();
	add_dialog_str(0,"A frozen corpse lies in the snow here. The body has been mangled by wolves, though that doesn't necessarily mean that wolves are what killed this man.",0);
	add_dialog_str(1,"A horrifying idea suddenly strikes you, you recall that Ainsley said the Beast attacked he and the others across the creek and to the north; what if this were the spot?",0);
	add_dialog_str(2,"You approach with dread, hoping against hope that this isn't the body of your old friend. It takes you longer than it should to satisfy yourself that it isn't.",0);
	add_dialog_str(3,"As unpleasant as searching the corpse was, it isn't a fruitless effort, the man was apparently once a soldier, and wears a rusted set of old plate armor. Clunky, but effective at protecting you.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	set_flag(2,6,1);
}
break;

beginstate 14;
if(get_flag(2,7) == 0){
	set_flag(2,7,1);
	message_dialog("A pack of wolves approaches you warily. Hunger burns behind their eyes and is apparent in their gaunt legs. The worst off have ribs showing beneath their pelts.","Rowly's theory about dwindling dear population contributing to the Beast's attacks could be the cause here as well, however; you don't have much time to ponder it before they attack.");
	activate_hidden_group(5);
	if(get_flag(2,20) > 0)
		erase_char(4);
}
break;

beginstate 15;
if(get_flag(2,9) == 0){
	set_flag(2,9,1);
	message_dialog("This icy cold creek is the same that ran down to your camp. During the winter these waterfalls must be solid ice, but the rays of the summer sun have melted all but a few chunks of ice.","Nonetheless a quick test with your finger shows the water to be ice cold. Wading across is out of the question, thinking about Ainsley and Jamie swimming in this makes you shudder.");
}
break;

beginstate 16;
block_entry(1);
message_dialog("This is the road you and Fabian recently treked, it will only take you back down to last night's camp.","");
break;

beginstate 17;
if(get_flag(2,10) == 0){
	set_flag(2,10,1);
	message_dialog("Water rushes over the falls before it continues it's leisurely course throught he mountains. Unfortunately it falls on several rocks below, which send a fine spray into the air.","The spray feels like a slap of cold in your face. There isn't enough to truly soak your clothes, but it makes you uncomfortable for the time until it dries.");
}
break;

beginstate 18;
if(get_flag(2,11) == 0){
	set_flag(2,11,1);
	reset_dialog();
	add_dialog_str(0,"You never thought you'd be this happy to see a group of ravenous wolves; but the key here is that THIS group of wolves is in plain sight, not sneaking up to attack.",0);
	add_dialog_str(1,"Maybe you're getting better at moving through these woods, or maybe these wolves just aren't very attentive. Whatever it is, you managed to approach them unseen.",0);
	add_dialog_str(2,"These wolves will pose a threat to the expedition until killed, else you would be more than happy to simply sneak past. You nod to Fabian, who eases his sword from its scabbard. You do likewise, then charge into the clearing.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	erase_char(41);
	erase_char(50);
	erase_char(55);
	if(get_flag(2,20) > 0)
		erase_char(4);
	activate_hidden_group(1);
	tick1 = 1;
}
break;

beginstate 19;
if(get_flag(2,13) == 0){
	print_str_color("Not during combat!",1);
	block_entry(1);
	end();
}
if(get_flag(2,14) == 0){
	block_entry(1);
	message_dialog("Fabian stops you, _I think we've gone far enoguh, Vincent. Look, the sun is low in the sky and the others haven't even caught up yet. Lets look for shelter closer by and wait for Burden and the rest before going higher into the mountains._","");
	end();
}
if(get_flag(3,3) == 0){
	block_entry(1);
	message_dialog("The others have gone to the small cave to camp the night. You should do the same for now, there's no point in wandering off on your own unless you have a goal in mind.","");
	end();
}
if((get_flag(4,5) > 0) && (get_flag(3,11) == 0)){
	block_entry(1);
	message_dialog("If you are to prevent the others from falling to the same fate as Erasmus, you have to carry on towards the cave. There is not much time.","");
}
if((get_flag(3,11) > 0) && (get_flag(2,25) == 0)){
	block_entry(1);
	message_dialog("Your expedition is over. Sergeant Burden has ordered you to hike down the mountain, not further up. You turn back, orders are to be obeyed even if they aren't agreed with.","");
	end();
}
	move_to_new_town(4,14,53);
break;

beginstate 20;
if(get_flag(2,13) == 0){
	print_str_color("Not during combat!",1);
	block_entry(1);
	end();
}

if(get_flag(3,11) > 0){
	block_entry(1);
	message_dialog("You heard Orrin-- if you stay in this cave you'll get snowed in. The bank of snow in the entrance is already waste high and the storm shows no sign of relenting, you can see why he was concerned.","You turn away. Your duty is elsewhere.");
	end();
}
if(get_flag(2,16) == 0)
	message_dialog("This is what you've been looking for, why Burden risked marching higher into the mountains; in the sheer rock face is a small opening.","Wolf tracks criss cross the snow at the mouth of this cave, you look over at Fabian, _Well, there's nothing for it but to go in. This is what we are looking for, and the sooner we clear it out the sooner we can rest._ You cautiously enter the cave.");
set_flag(2,16,1);
move_to_new_town(3,26,16);
break;

beginstate 21;
if((get_flag(2,15) > 0) && (get_flag(2,14) == 0)){
	set_flag(2,14,1);
	begin_talk_mode(14);
}
break;

beginstate 22;
if((get_flag(4,5) > 0) && (get_flag(4,12) == 0)){
	set_flag(4,12,1);
	message_dialog("A lurid sight awaits your eyes at the clearing. Half of a flayed wolf carcass hangs from the once impressive pine tree that now leans awkwardly. Heavy claw marks gouge the bark about eight feet up on the trunk-- what the hell is going on here?","You cautiously approach the carnage, keeping your head on a swivel for any sign of danger. The ground here is even bloodier than when you left, and another noteworthy body has been added to that of the slayed wolves-- Sir Rowly.");
}
break;

beginstate 23;
if((get_flag(4,5) > 0) && (get_flag(4,13) == 0)){
	block_entry(1);
	message_dialog("The clearing behind you is strewn with bodies, presumably the work of the Beast, and one of your expedition's members lies a short walk away. How could you leave when there could potentially be valuable information here?","");
}
break;

beginstate 24;
if((get_flag(4,13) > 0) && (get_flag(4,14) == 0)){
	block_entry(1);
	message_dialog("As you approach the cave you hear the sounds of battle, and break into a run. You round the corner at a dead sprint, and screech to a halt when you see Orrin ahead of you.","He holds an unsheathed sword in each hand and stands staring up at the cliff wall. You follow his gaze up the sheer wall and see a sight straight out of a nightmare-- straight out of YOUR nightmare.");
	relocate_character(67,4,26);
	force_view_center(6,23);
	force_instant_terrain_redraw();
	pause(3);

	relocate_character(67,3,26);
	force_instant_terrain_redraw();
	pause(3);

	relocate_character(67,2,26);
	force_instant_terrain_redraw();
	pause(3);

	relocate_character(67,1,26);
	force_instant_terrain_redraw();
	pause(3);

	relocate_character(67,0,26);
	force_instant_terrain_redraw();
	pause(3);

	erase_char(67);
	reset_dialog();
	add_dialog_str(0,"The monstrous form leaps and scrambles up the almost vertical cliff. It drags a piece of meat, a wolf carcass, in one of it's massive claws, and leaves a trail of blood in the snow from multiple injuries.",0);
	add_dialog_str(1,"You stare up at the cliff even after it disappears from view, half dreading that it might return and half wishing it would do just that so you can end this now. Several of your friends cautiously emerge from the cave with weapons at the ready.",0);
	add_dialog_str(2,"Orrin's shoulders heave as he fights to get air to his worn muscles. The others wait until he can gasp out a report. _It's gone-- for now. The fire seemed to scare it off._",0);
	add_dialog_str(3,"At this point he realizes that you are here, _Vincent! It is good that you got back in one piece, these woods are no longer safe to wander alone. Erasmus and Rowly.... ?_ You sadly inform the group of the two men's deaths.",0);
	add_dialog_str(4,"Everybody stands in silence. The moments stretch into minutes until it seems nobody will speak, then Sergeant Burden snaps the silence, _Let's get inside the cave, there's no use in standing out here in the snow._",0);
	add_dialog_str(5,"The others turn file into the cave. Burden does the same, then as an afterthought turns to ask you a question, _So... Did you get that firewood?_ You slap yourself on the forhead and apologize, you must have dropped it back when you saw Erasmus.",0);
	add_dialog_str(6,"You add that you'll go get it and be back in a hurry, but Orrin stops you. _I'll fetch the wood, and retrieve the bodies of Erasmus and Rowly. They shouldn't be left to the animals._ You consent, and follow the others into the cave.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	set_flag(4,14,1);
	move_to_new_town(3,19,15);
}
break;

beginstate 25;
if((get_flag(3,11) > 0) && (get_flag(2,25) == 0)){
	set_flag(2,25,1);
	block_entry(1);
	play_sound(108);
	force_view_center(38,39);
	force_instant_terrain_redraw();
	play_sound(108);

	reset_dialog();
	add_dialog_str(0,"You hear a rumbling noise from the mountains above you. Your eyes are drawn to the rocks resting precariously on the cliff wall further down the path.",0);
	add_dialog_str(1,"The source of the noise doesn't stay a mystery for longer than a moment, a wave of white cold white snow flys down the slope, carrying rocks and debris down with it.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	
	xfall = 36;
	while(xfall <= 42){
		yfall = 38;
		while(yfall <= 40){
			set_terrain(xfall,yfall,get_ran(1,134,136));
			if(get_ran(1,0,5) == 0)
				play_sound(108);
			yfall = yfall + 1;
		}
		xfall = xfall + 1;
	}
	reset_dialog();
	add_dialog_str(0,"The group stares agape at the doom that would have befallen you if you'd been a few steps ahead. Sergeant Burden looks particularly ashen as she surveys the new impasse.",0);
	add_dialog_str(1,"She turns to Orrin, _There-- there is another way down from here, right?_ Orrin shakes his head, _Not that I know of, at least not without hiking to Gerund's pass, but that's two day's hike from here._",0);
	add_dialog_str(2,"She poses the same question to Jamie, _Jamie, is there any other way?_ Jamie replies, _Err, no. Orrin's right, we're in a rough area and there's no way down for miles._",0);
	add_dialog_str(3,"She stands in silence, turning this over in her mind. _No, no there must be another way down. We -- we can climb down. We can use ropes and climb down. We can-- we can._",0);
	add_dialog_str(4,"She trails off, realising just how ridicuous the idea of Ainsley climbing down a cliff is. She erupts in frustration, _THIS WAS SUPPOSED TO BE OVER, WE WERE SUPPOSED TO BE LEAVING. I WAS FINALLY FREE BUT NOW, BUT NOW...._",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);

	reset_dialog();
	add_dialog_str(0,"Her tirade is interupted only when Captain Ainsley strides over and grabs her by the shoulders. He nearly shakes with the effort, but he stares her in the eyes and shouts:",0);
	add_dialog_str(1,"_You're right, Marie, you're right. If you give up on these men, abandon us to your despair, then this IS all your fault, then you really ARE a coward. If you give in to fear then you ARE a failure, and what I saw in you was naught but a lie._",0);
	add_dialog_str(2,"_So if you have any mettle left in your body, if you have any courage, any determination-- then you'll lead these men to safety._ He lets go of her shoulders and turns away weakly, _I can't, Marie. I'm too weak. But you can._",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);

	reset_dialog();
	add_dialog_str(0,"Sergeant Burden stands silently, staring out over the mountains to the south. She slowly straightens up, and her face begins to recover its color. When she speaks her voice carries a new strength.",0);
	add_dialog_str(1,"_Vincent!_ You step over and salute. _Vincent, you were the last one to speak to Erasmus, you were the one he showed that book to. Where was he planning to take us? Where did he want to go?_",0);
	add_dialog_str(2,"You pull out the black book, and after some concentration relate to her what Erasmus told you. She nods, _And you found this landmark he sent you for?_ You nod.",0);
	add_dialog_str(3,"She turns to the group and announces, _Well then we head for Amon Sul. If the tower still stands then we'll find it. We'll weather this storm, then slay that stinking animal._",0);
	add_dialog_str(4,"Ainsley nods with satisfaction at this sudden transformation, and the rest stand speechless. _Well, stop standing around and march. It isn't getting any warmer._ You file out.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
}
break;

beginstate 26;
if(get_flag(3,11) == 0){
	message_dialog("This looks like a patch of Karao flowers, a valuable magical regeant that thrives in the mountains. These flowers, however, don't look quite ripe.","");
	end();
}
if(get_flag(252,3) > 0)
	end();
print_str_color("You successfully harvest Karao Blossoms.",4);
set_flag(252,3,1);
reward_give(473);
if(get_flag(250,4) == 0){
	reset_dialog();
	add_dialog_str(0,"You find a patch of delicate flowers growing here, an apparently impossible occurence. However when you inspect the flowers closer you notice a faint glow about them, and instantly understand how these fragile plants survive here.",0);
	add_dialog_str(1,"These are Karao Blossoms, a rare and potent regeant. A delicate plant needs all the advantages it can get in extreme climates like the Rim.",0);
	add_dialog_str(2,"Karao blossoms survive because of their powerful magical properties. They are saught by alchemists for the same reason. You gently pluck the brightest blossom in the patch.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	set_flag(250,4,1);
}
break;

beginstate 27;
if((get_flag(4,5) > 0) && (get_flag(4,13) == 0)){
	block_entry(1);
	message_dialog("The clearing behind you is strewn with bodies, presumably the work of the Beast, and one of your expedition's members lies a short walk away. How could you leave when there could potentially be valuable information here?","");
}
if((get_flag(4,13) > 0) && (get_flag(3,11) == 0)){
	block_entry(1);
	message_dialog("Trekking down the mountain isn't a priority right now. Your friends are in danger.","");
}
break;

beginstate 99;
block_entry(1);
break;

beginstate 100;
if(get_flag(3,11) > 0)
	block_entry(1);
break;

beginstate 101;
	set_flag(2,20,1);
	message_dialog("Fabian falls to the ground, worn down by exhaustion, the cold, and his many wounds. He quickly scrambles up and leaves the battle, saying _Sorry Vincent, you'll have to handle the rest of them on your own, I'm done for now._","");
break;
