begintownscript;
variables;
short choice;
short i,erase,march,steps;
short tick,counter = 0;

body;
beginstate init_state;
turn_off_training(1);
set_flag(6,23,0);
i = 0;
while(char_ok(i) == 0){
	i = i + 1;
	}
reset_dialog();
add_dialog_str(0,"You scramble up the slope at a dead run, and almost cry with joy when you smell the fresh mountain air and see the light of the full moon. The cold puts a bit of a damper on your elation, but its still good to be out of the twisting subteranean lair.",0);
add_dialog_str(1,"There isn't time for celebration though, you can already here the goblins giving chase. Sergeant Burden waits at the top of the slope to make sure everybody has gotten out safely, you're the last one out.",0);
add_dialog_str(2,"She sprints off after the others, who are a hundred paces ahead or so. _Get that lead out of your ass, Vincent! We aren't out of here yet!_",0);
add_dialog_str(3,"The baying of wargs from behind you serves as a much better motivator than any of Burden's words. You tear off after her, trying to make as good a speed as you can in the deep snow.",0);
add_dialog_choice(0,"OK");
choice = run_dialog(1);
break;

beginstate start_state;
if((get_flag(7,0) > 0) && (num_chars_in_group(1) == 0) && (get_flag(7,1) == 0)){
	set_flag(7,1,1);
	message_dialog("The last warg rider tumbles to the snow, but you can already hear the next wave howling in the distance.","Sergeant Burden doesn't bother to sheath her sword, she is already sprinting south at top speed. _Come on Vincent, we have ground to make up!_ You don't need to be told twice._");
	counter = 0;
}

if((get_flag(7,2) > 0) && (num_chars_in_group(2) == 0) && (get_flag(7,3) == 0)){
	set_flag(7,3,1);
	message_dialog("Your ambush was a success! The last goblin rider lies face down, turning the snow a sickly green with its blood.","Burden grabs you by the arm and starts running, _Let's go, let's go! They're getting closer!_ The mad dash begins again.");
	counter = 0;
}
if((get_flag(7,4) > 0) && (num_chars_in_group(3) == 0) && (get_flag(7,5) == 0)){
	set_flag(7,5,1);
	message_dialog("A great howl goes up from behind you-- the main host is getting closer. Sergeant Burden was sprinting down the trail before the last rider even hits the snow, the closeness of the baying wargs lending urgency to her pace.","_It can't be much further. We can make it to the tower, just hurry!_ Another cry goes up from your pursuers, a cacophany of howls and barks. _Just HURRY!_");
	counter = 0;
}

if((get_flag(7,1) == 0) && (counter >= 38)){
	message_dialog("You flounder through the snow as the main host of riders draws nearer and nearer. You can stand against a few isolated wargs, but against the larger part of their force you are helpless.","You soon find out that hobgoblins are remarkably skilled at making even a fast death an intensely painful one.");
	kill_char(i,2,0);
}
if((get_flag(7,1) > 0) && (get_flag(7,3) == 0) && (counter >= 45)){
	message_dialog("You flounder through the snow as the main host of riders draws nearer and nearer. You can stand against a few isolated wargs, but against the larger part of their force you are helpless.","You soon find out that hobgoblins are remarkably skilled at making even a fast death an intensely painful one.");
	kill_char(i,2,0);
}
if((get_flag(7,3) > 0) && (get_flag(7,5) == 0) && (counter >= 45)){
	message_dialog("You flounder through the snow as the main host of riders draws nearer and nearer. You can stand against a few isolated wargs, but against the larger part of their force you are helpless.","You soon find out that hobgoblins are remarkably skilled at making even a fast death an intensely painful one.");
	kill_char(i,2,0);
}
if((get_flag(7,5) > 0) && (get_flag(7,6) == 0) && (counter >= 22)){
	message_dialog("You flounder through the snow as the main host of riders draws nearer and nearer. You can stand against a few isolated wargs, but against the larger part of their force you are helpless.","You soon find out that hobgoblins are remarkably skilled at making even a fast death an intensely painful one.");
	kill_char(i,2,0);
}
if((get_flag(7,6) == 1) && (counter >= 6) && (get_flag(7,13) == 0)){
	set_flag(7,13,1);
	message_dialog("It seems that as many goblins as you kill, there are always more to fill in the ranks. There isn't a place to rest your eyes where you don't gaze at the powerful jaws of a warg or the frenzied bloodshot eyes of a hobgoblin.","There is no hope-- no way that such a small group can stand up to a horde like this. Still-- you stand firm with your back against your friend's. What choice do you have but to die fighting?");
}
if((get_flag(7,6) == 1) && (counter >= 12)){
	set_flag(7,6,2);
	reset_dialog();
	add_dialog_str(0,"This battle was over before it even began, both sides have known all along who the victor would be. One is determined to sell their lives at as dear a cost as possible, the other to rend them limb from limb.",0);
	add_dialog_str(1,"Then suddenly all the hobgoblins halt. The wargs prick up their ears, and begin whining piteously, the hobgoblins jabber amongst themselves nervously, gradually escalating into open panic.",0);
	add_dialog_str(2,"Suddenly one of them wheels its warg and spurs it back down the trail. A panicked chaos breaks out amongst the remaining goblins, who are practically fighting each other to be the first to retreat. The clearing is empty in less than a minute.",0);
	add_dialog_str(3,"You stand in dumb awe at this spectacle, unable to comprehend what just happened. Fabian sums up everybody's feelings by laughing, _What the bloody hell? What just happened? Where are they going....._",0);
	add_dialog_str(4,"His question is answered when a wailing roar sounds from the south, a deep rumbling noise that bounces off the cliff walls, a roar that you can feel in your gut better than you can hear. The roar you were sent here to silence.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	erase = 6;
	while(erase <= 119){
		if(creature_type(erase) == 252)
			erase_char(erase);
		erase = erase + 1;
	}
	pause(5);

	reset_dialog();
	add_dialog_str(0,"The previous looks of perplexed happiness melt away like wax, as what looked like the windfall of a lifetime reveals itself to be simply a death sentence of a different nature.",0);
	add_dialog_str(1,"Fabian licks his lips nervously, _Wha- what do we do? I-- I know we're supposed to kill that thing eventually, but-- I can hardly even stand._ The rest of the group looks no better.",0);
	add_dialog_str(2,"Sergeant Burden stares up the cliff at the tower above you, sizing up how long it would take you to reach it. She comes to her conclusion quickly. _We run, that's what we do. We fly with every ounce of strength in our bodies._",0);
	add_dialog_str(3,"Nobody voices any dissent. Another roar this time a bit nearer sends everybody scrambling up the path. The race for safety begins again, this time with legs that feel like lead, and a far deadlier foe at your back.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	counter = 0;
	erase = 6;
	while(erase <= 119){
		erase_char(erase);
		erase = erase + 1;
	}
	award_party_xp(400,15);
}
if((get_flag(7,6) == 2) && (counter >= 150) && (get_flag(7,7) == 0)){
	message_dialog("You never saw it coming, or rather you saw it coming the first time you heard the Beast's roar. It came from somwhere behind and above you, though you heard nothing of it until you were already dead.","You certainly didn't have time to react before the weight struck you in the back, pinning you face down in the snow and.... you aren't alive long enough to really know the details of your death, probably best that way.");
	kill_char(1000,2,0);
}

if(is_combat() > 0){
	if((get_flag(7,0) > 0) && (get_flag(7,1) == 0))
		counter = counter - 2;
	if((get_flag(7,2) > 0) && (get_flag(7,3) == 0))
		counter = counter - 2;
	if((get_flag(7,4) > 0) && (get_flag(7,5) == 0))
		counter = counter - 2;
	if(get_flag(7,6) == 1)
		counter = counter - 2;
	counter = counter + 2;
}
counter = counter + 1;
break;

beginstate exit_state;
break;

beginstate 10;
block_entry(1);
message_dialog("There could not possibly be a worse place to run to than the goblin lair, except perhaps off the edge of a cliff.","You turn back and begin running down the trail, you have to catch up with the others and the baying of the wargs is getting closer.");
break;

beginstate 11;
if(get_flag(7,0) == 0){
	set_flag(7,0,1);
	reset_dialog();
	add_dialog_str(0,"Burden pulls up as the howling draws closer. Her sword is out of its sheath in a twinkling. _Let's buy the others some time, what do you say Vincent?_ You nod and draw your own weapon.",0);
	add_dialog_str(1,"You don't have long to wait. The leading rider bears down on you, the goblin screaming at the top of its voice and the warg slavering and howling, kicking up snow with its powerful back legs.",0);
	add_dialog_str(2,"Burden stand her ground as it charges her with lowered spear. At the last moment she rolls out of the way, and hamstrings the beast with a flash of her sabre. You don't have time to marvel at her sword skill, the next wave is already here.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	activate_hidden_group(1);
}
break;

beginstate 12;
if(get_flag(7,1) == 0){
	block_entry(1);
	message_dialog("Sergeant Burden stops you, _We're trying to buy the others some time to get away, we can catch up once we kill some more of those riders._ You turn back.","");
	end();
}
if(get_flag(7,2) == 0){
	set_flag(7,2,1);
	message_dialog("Sergeant Burden ducks around the corner and motions for you to do the same. You crouch in wait for the warg riders with blades bare. You don't wait long until the first rounds the corner, but Burden holds you back for a moment.","You wait until the first two riders gallop past, then leap out at the next that passes. Confusion breaks out amongst the riders as they break rank to deal with the new attackers, and riders ahead wheel about to come to their fellows' aid.");
	activate_hidden_group(2);
}
break;

beginstate 13;
if(get_flag(7,3) == 0){
	block_entry(1);
	message_dialog("Sergeant Burden stops you, _We're trying to buy the others some time to get away, we can catch up once we kill some more of those riders._ You turn back.","");
	end();
}
if(get_flag(7,4) == 0){
	set_flag(7,4,1);
	message_dialog("The yelping of the wargs trailing you is growing closer. The others are just a hundred paces ahead, and with wargs literally snapping at your heels this can only mean one thing: you need more time.","Sergeant Burden suddenly yells, _NOW!_ and with that she pivots and launches herself at the nearest rider, only a few steps back. You do the same.");
	activate_hidden_group(3);
}
break;

beginstate 14;
if(get_flag(7,5) == 0){
	block_entry(1);
	message_dialog("Sergeant Burden stops you, _We're trying to buy the others some time to get away, we can catch up once we kill some more of those riders._ You turn back.","");
	end();
}

if(get_flag(7,6) == 1){
	block_entry(1);
	message_dialog("The shout of battle from behind you causes you to turn. Your allies are surrounded by howling warg riders, and retreat is not an option. You turn back to do what you can to help.","");
	end();
}

if(get_flag(7,6) == 2){
	block_entry(1);
	message_dialog("This way leads only to the goblin lair, the haven of Amon Sul lies higher up still.","The tower is tantalizingly close, but still seemingly out of reach with the Beast bearing down on you. Back tracking won't make it any easier.");
	end();
}

if(get_flag(7,6) == 0){
	block_entry(1);
	set_flag(7,6,1);
	erase_char(4);
	activate_hidden_group(8);
	relocate_character(i,42,57);
	set_character_facing(i,6);
	force_instant_terrain_redraw();
	reset_dialog();
	add_dialog_str(0,"You and Sergeant Burden finally catch up with the others. Everybody is beginning to show sign of weariness, except Orrin that is, who has somehow managed to keep up with the group despite the fact he carries Captain Ainsley upon his shoulders.",0);
	add_dialog_str(1,"Burden shouts encouragement to the others, whose steps are beginning to falter as breath gets shorter and endurance ebbs away, _Let's go, let's go! We can make it, they're close but we can make it!_",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);

	steps = 0;
	while(steps < 4){
		march = 56;
		while(march <= 62){
			relocate_character(march,char_loc_x(march) + 1,char_loc_y(march));
			march = march + 1;
		}
		relocate_character(i,char_loc_x(i) + 1,char_loc_y(i));
		force_view_center(46 + steps,56);
		force_instant_terrain_redraw();
		pause(5);
		play_sound(50);
		steps = steps + 1;
	}
	march = 56;
	while(march <= 61){
		set_character_facing(march,0);
		march = march + 1;
	}
	relocate_character(i,char_loc_x(i) + 1,char_loc_y(i));
	relocate_character(62,char_loc_x(62) + 1,char_loc_y(62));
	force_instant_terrain_redraw();
	pause(4);
	play_sound(50);

	reset_dialog();
	add_dialog_str(0,"As you round the corner another cry goes up from the wargs behind you. But that hardly even puts a damper on your elation at the sight ahead of you-- Amon Sul.",0);
	add_dialog_str(1,"The crumbling remains of the tower overlooks the cliff in front of you. A twisting path winds up the the 100 foot cliff to the tower.",0);
	add_dialog_str(2,"Sergeant Burden grins ear to ear, she's almost giddy with excitement _Erasmus didn't lead us wrong! Run men, run! There it is, we're going to make it, don't let up now!_",0);
	add_dialog_str(3,"Nobody needs her urging this time, it's easy to forget burning muscles when the goal is in sight.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);

	steps = 0;
	set_character_facing(i,0);
	set_character_facing(62,0);
	while(steps < 3){
		march = 56;
		while(march <= 62){
			relocate_character(march,char_loc_x(march) + 1,char_loc_y(march) - 1);
			march = march + 1;
		}
		relocate_character(i,char_loc_x(i) + 1,char_loc_y(i) - 1);
		force_view_center(char_loc_x(i),char_loc_y(i));
		force_instant_terrain_redraw();
		pause(3);
		steps = steps + 1;
		play_sound(50);
	}
	steps = 0;
	while(steps < 4){
		march = 56;
		while(march <= 62){
			relocate_character(march,char_loc_x(march),char_loc_y(march) - 1);
			march = march + 1;
		}
		relocate_character(i,char_loc_x(i),char_loc_y(i) - 1);
		force_view_center(char_loc_x(i),char_loc_y(i));
		force_instant_terrain_redraw();
		pause(3);
		play_sound(50);
		steps = steps + 1;
	}
	steps = 0;
	while(steps < 4){
		march = 56;
		while(march <= 62){
			relocate_character(march,char_loc_x(march) - 1,char_loc_y(march) - 1);
			march = march + 1;
		}
		relocate_character(i,char_loc_x(i) - 1,char_loc_y(i) - 1);
		force_view_center(char_loc_x(i),char_loc_y(i));
		force_instant_terrain_redraw();
		pause(3);
		steps = steps + 1;
		play_sound(50);
	}
	march = 56;
	while(march <= 61){
		set_character_facing(march,2);
		text_bubble_on_char(march,"!");
		march = march + 1;
	}
	set_character_facing(i,2);
	set_character_facing(62,2);
	force_instant_terrain_redraw();
	play_sound(33);	
	pause(3);
	play_sound(48);
	pause(5);

	activate_hidden_group(6);
	force_view_center(45,44);
	force_instant_terrain_redraw();

	relocate_character(44,42,47);
	relocate_character(42,42,44);
	relocate_character(50,41,41);
	force_instant_terrain_redraw();
	pause(5);

	relocate_character(44,43,47);
	relocate_character(42,43,44);
	relocate_character(50,43,42);
	set_character_pose(42,1);
	set_character_pose(50,1);
	force_instant_terrain_redraw();
	pause(3);
	play_sound(48);

	relocate_character(44,44,46);
	relocate_character(42,44,44);
	relocate_character(50,44,42);
	set_character_pose(44,1);
	force_instant_terrain_redraw();
	pause(3);
	play_sound(48);

	relocate_character(44,45,46);
	relocate_character(42,45,44);
	relocate_character(50,45,42);
	march = 56;
	while(march <= 62){
		relocate_character(march,char_loc_x(march) + 1,char_loc_y(march));
		march = march + 1;
	}
	relocate_character(i,char_loc_x(i) + 1,char_loc_y(i));
	force_instant_terrain_redraw();
	pause(3);
	play_sound(33);

	relocate_character(44,46,46);
	relocate_character(42,46,44);
	relocate_character(50,46,42);
	march = 56;
	while(march <= 62){
		set_character_pose(march,2);
		relocate_character(march,char_loc_x(march) + 1,char_loc_y(march));
		march = march + 1;
	}
	set_character_pose(i,2);
	relocate_character(i,char_loc_x(i) + 1,char_loc_y(i));
	set_character_pose(42,0);
	set_character_pose(44,0);
	set_character_pose(50,0);
	force_instant_terrain_redraw();
	pause(5);

	message_dialog("The elation fades as quickly as it came. Warg riders scream lustily as they leap down the slope, your enemy knows these mountains better than you and managed to cut you off. Any chance of outrunning the main pack of wargs is now gone.","You back further and further away as more riders launch down the hill ahead, and the cries of the main host get closer and closer. _Form ranks._ Burden says calmy, her voice not carrying a hint of the despair everybody in the group feels."); 
	march = 56;
	while(march <= 62){
		erase_char(march);
		march = march + 1;
	}
	relocate_character(i,52,52);
	force_view_center(52,52);
	activate_hidden_group(4);
	activate_hidden_group(5);
	alter_stat(16,3,2);
	alter_stat(11,9,3);
	alter_stat(16,3,1);
	alter_stat(16,6,4);
	alter_stat(16,9,1);
	alter_stat(23,3,1);
	alter_stat(23,4,1);
	alter_stat(23,5,1);
	alter_stat(23,9,1);
	alter_stat(22,3,3);
	alter_stat(22,4,1);
	alter_stat(22,5,1);
	alter_stat(22,8,4);
	alter_stat(22,9,1);
	alter_stat(24,0,1);
	alter_stat(24,3,4);
	alter_stat(24,4,2);
	alter_stat(24,5,2);
	alter_stat(24,9,4);
	force_instant_terrain_redraw();
	pause(8);

	reset_dialog();
	add_dialog_str(0,"First you hear them, the howling of hundreds of wargs growing gradually louder. Then you see the snow kicked up by the creatures as they bound through the snow, which forms a cloud of white above them.",0);
	add_dialog_str(1,"And now you are surrounded. The goblins ride in circles around you screaming and howling, working up their thirst for blood and preparing to charge. When the ring is closed they each lower their spears.",0);
	add_dialog_str(2,"_Whatever you do,_ Sergeant Burden whispers, _whatever you do, don't break ranks. In the name of all that is good, don't break ranks._ Easier said than done-- the goblins charge.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
	counter = 0;
}
break;

beginstate 15;
if(get_flag(7,6) == 1){
	block_entry(1);
	message_dialog("The shout of battle from behind you causes you to turn. Your allies are surrounded by howling warg riders, and retreat is not an option. You turn back to do what you can to help.","");
	end();
}
break;

beginstate 16;
if(get_flag(7,8) == 0){
	set_flag(7,8,1);
	message_dialog("This trail winds higher into the mountains, hopefully leading to the ruined tower overlooking the peak above you.","If it doesn't you'll be finding out for sure if the Beast can be killed-- another roar tells you time is short-- but for now you must summon every ounce of strength in your legs and run. The alternative hardly bears thinking about.");
}
break;

beginstate 17;
if(get_flag(7,9) == 0){
	set_flag(7,9,1);
	reset_dialog();
	add_dialog_str(0,"You lurch through the snow, and nearly fall flat on your face when you plant on a leg that simply refuses to obey you. Sergeant Trey catches your arm, _Move-- keep moving. Don't stop, not when we're this close. I won't let you stop._",0);
	add_dialog_str(1,"You can't feel your limbs, the only way you know they're tired is that they won't move without the greatest effort. The cold has soaked through your clothes and stolen away every ounce of heat in your body. And still you run.",0);
	add_dialog_str(2,"Another howl, this one startlingly close, but neither you nor the others pay it hardly any heed. Everybody is too busy fighting exhaustion, fighting the cold, and always-- always moving.",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
}
break;

beginstate 18;
if(get_flag(7,10) == 0){
	set_flag(7,10,1);
	activate_hidden_group(7);
	set_char_dialogue_pic(69,304,0);
	reset_dialog();
	add_dialog_str(0,"Each step is like a fight against yourself, convincing your legs to lift, to force your tired body to your will. Each pace makes your legs more stubborn, more determined to stay rooted in the snow.",0);
	add_dialog_str(1,"Then-- a cry from one of your companions ahead. You lift your head to see what it's about and your hope soars, the ruined top of the watchtower looms ahead. Tantalisingly close. So close you could surely reach it before your imminent collapse.",0);
	add_dialog_str(2,"The others come to the same conclusion, limbs continue to churn mechanically but this time with renewed vigor. But then-- another howl, a howl that seems to surround you, to draw closer and closer even as it hangs reverbating in the air.",0);
	add_dialog_str(3,"_We-- we'll never make it._ You aren't sure who says it, but you all feel it. Burden recites as if by rote, _Run, if you think you can stop now-- we'll make it, goddamn it we'll make it._",0);
	add_dialog_str(4,"Left foot, right foot-- just keep running-- left foot, right foot-- what else can you do? Left foot, right foot-- and then..... halt?",0);
	add_dialog_choice(0,"What?");
	choice = run_dialog(1);

	reset_dialog();
	add_dialog_str(0,"Orrin stops, the mountain of a highlander who has plowed forward like a machine. Like an ustoppable juggernaut he has marched with no sign of flagging. And now he's.... stopped?",0);
	add_dialog_str(1,"Your eyes don't deceive you, he has halted and is unshouldering Captain Ainsley, who he has been carrying like a sack of grain all the while. He wordlessly hands him over to Private Evrey.",0);
	add_dialog_str(2,"_Orrin, are you alright?_ Evrey stammers out in consternation, _Is something the matter, do you need...._ Orrin holds his had up to cut him off, _No, Evrey, this is just a weight that you must carry now._",0);
	add_dialog_str(3,"Evrey quietly hefts the limp body of Ainsley. The others stare in silence, unsure of what's going on. Burden's shout wakens them from their stupor, _Well what the hell you waiting for? March damn it!_ They move out.",0);
	add_dialog_str(4,"Orrin stands unmoving. Sergeant Burden begins to depart, but turns to say simply, _Farewell, soldier._ She salutes him and marches away, vanishing around the corner ahead.",0);
	add_dialog_str(5,"You stand in shock, wondering what just transpired. Orrin looks over at you, _Well, Vincent, I told you this time would come that very first night._ Another roar punctuates his sentence. _Yes,_ he smiles, _this is why I'm here._",0);
	add_dialog_choice(0,"OK");
	choice = run_dialog(1);
}
break;

beginstate 19;
if(get_flag(7,7) > 0){
	if(get_flag(7,11) > 0){
		block_entry(1);
		message_dialog("Orrin stands alone in the snow, the wind whips through the pass, but doesn't seem to touch the highlander.","He rises up from the ground as though carved out of the rock of the mountain itself, an indomitable figure. You turn back, if anybody can handle the Beast it is Orrin, and you certainly have no help to add. You are needed elsewhere."); 
	}
	end();
}
if(get_flag(7,10) > 0){
	block_entry(1);
	message_dialog("Orrin stands alone at the pass, and although the others turned the corner up ahead already, he shows no sign of following.","The Beast is getting closer, and yet your friend stands like a statue. You can't leave him here, not after all he's done for you. Every nerve in your body urges you to flee, but you slowly turn around.");
}
break;

beginstate 20;
if(get_flag(7,11) == 0){
	set_flag(7,11,1);
	message_dialog("You spare one last look back at the lonely figure behind you. Orrin stands shirtless, stripped to bare skin, with head thrown back and swords raised in defiance of all the mountain has thrown against him.","You have little doubt that if you could see your friend's face it would be grinning with ecstasy. You can summon no tears for him, they aren't needed here.");
}
break;

beginstate 21;
if(get_flag(7,12) == 0){
	set_flag(7,12,1);
	message_dialog("Wind whips through the narrow pass in front of you, and the rock walls on either side of the pass fall away into sheer cliffs.","You don't have time to consider how far the fall would be, there is worse danger behind you. You stumble on.");
}
if(get_flag(7,7) == 1){
	block_entry(1);
	message_dialog("Your place is with your fellows, Orrin has made this clear to you. There is nothing you can do here; the road to Amon Sul and surely more difficulties lies the in the other direction.","");
	end();
}
if(get_flag(7,10) > 0){ 
	block_entry(1);
	message_dialog("Orrin stands alone at the pass, and although the others turned the corner up ahead already, he shows no sign of following.","The Beast is getting closer, and yet your friend stands like a statue. You can't leave him here, not after all he's done for you. Every nerve in your body urges you to flee, but you slowly turn around.");
	end();
}
break;

beginstate 22;
move_to_new_town(8,2,6);
break;

beginstate 101;
//fabian
	set_state_continue(105);
break;

beginstate 102;
//orrin
	set_state_continue(105);
break;

beginstate 104;
//burden
if(get_flag(7,6) > 0){
	set_state_continue(105);
	end();
}
reset_dialog();
add_dialog_str(0,"Sergeant Burden is sent reeling by the last blow, and lands face down in the snow. At first you think she's a goner, but she quickly regains her senses and adroitly regains her feet.",0);
add_dialog_str(1,"Nevertheless, apparently she's had enough fighting for now. _I-- I'll be right ahead, just hold them for a moment longer._ With that she extracates herself from the battle, leaving you alone.",0);
add_dialog_choice(0,"OK");
choice = run_dialog(1); 
break;

beginstate 105;
//the rest
play_sound(29);
if(get_flag(7,14) == 0){
	inc_flag(7,14,1);
	message_dialog("One of your fellows falls, stricken down by one of the many warg riders that surround you. The situation is growing increasingly grim, not long now before you fall apart altogether.","");
	end();
}
if(get_flag(7,14) > 0){
	inc_flag(7,14,1);
	message_dialog("Yet another of your fellows falls. The circle around you is growing tighter, and the strength of those left standing is beginning to waver. How much longer can you hold out?","");
	end();
}
break;