// vengenpc.txt
// Modifies basicnpc.txt, used by some of the elite soldier ghosts. When
//  killed, hurls its sword at whoever killed hit, striking for an amount
//  of unblockable damage specified in cell 4, as well as 35 cold damage.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - Amount of damage the hurled sword deals, multiplied by ten.

begincreaturescript;

variables;

short i,target;
string vengeance;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);

	if((get_memory_cell(4) != 0) && ((who_hit_me() >= 0) || (who_hit_me() <= 5))) {
		reset_dialog();
		clear_buffer();
		append_string("As you deal the soldier a final blow, he lets loose an almost primal scream of rage, and he hurls his ethereal sword at ");
		append_char_name(who_hit_me());
		append_string(" as if it were a javelin.");
		get_buffer_text(vengeance);
		add_dialog_str(0,vengeance,0);
		run_dialog(1);

		pause(3);

		play_sound(48);
		play_sound(14);
		put_effect_on_char(who_hit_me(), 11,1,2);
		run_animation_sound(112);
		damage_char(who_hit_me(), (get_memory_cell(4) * 10), 4);
		damage_char(who_hit_me(), 35, 5);

		pause(5);

		if(char_ok(who_hit_me()) == 1) {
			reset_dialog();
			clear_buffer();
			append_string("When the sword fails to kill ");
			append_char_name(who_hit_me());
			append_string(", the soldier simply sinks into the floor with a face full of cold rage.");
			get_buffer_text(vengeance);
			add_dialog_str(0,vengeance,0);
			run_dialog(1);
			}
		else {
			reset_dialog();
			clear_buffer();
			append_string("When the sword kills ");
			append_char_name(who_hit_me());
			append_string(", the soldier's fading form shakes with demented laughter as it sinks into the floor.");
			get_buffer_text(vengeance);
			add_dialog_str(0,vengeance,0);
			run_dialog(1);
			}

		}
	else {
		reset_dialog();
		add_dialog_str(0,"As you deal the soldier a final blow, he lets loose an almost primal scream of rage, and he sinks into the floor while thrashing wildly.",0);
		run_dialog(1);
		}
break;

beginstate START_STATE; 
	
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;