// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;
short last_abil_time;
short r1;

body;

beginstate INIT_STATE;
        set_name(ME,"Cerund");
        //set_level(ME,90);
        set_level(ME,70);
        break;

beginstate DEAD_STATE;
        //future code
break;

beginstate START_STATE; 
        // if I have a target for some reason, go attack it
        if (target_ok()) {
                if (dist_to_char(get_target()) <= 16) {
                        set_state(3);
                        set_mobility(ME,1);
                }
                        else set_target(ME,-1);
        }
        
        // Look for a target, attack it if visible
        if (select_target(ME,8,0)) {
                //do_attack_tactic(2);
                set_state(3);
                }
                
        // Have I been hit? Strike back!
        if (who_hit_me() >= 0) {
                set_target(ME,who_hit_me());
               //do_attack_tactic(2);
                set_state(3);
                }
                
        // Otherwise, just peacefully move around. Go back to start, if I'm too far
        // from where I started.
        if ((my_dist_from_start() >= 6) || (my_dist_from_start() > 0)) {
                if (get_ran(1,1,100) < 40) 
                        return_to_start(ME,1);
                }
                else if (get_memory_cell(0) == 0) {
                        fidget(ME,25);
                        }

        // if we're in combat and the above didn't give me anything to do, just
        // stop now. Otherwise, game will keep running script, and that eats up CPU time.
        if (am_i_doing_action() == FALSE)
                end_combat_turn();
break;

beginstate 3; // attacking
        if (target_ok() == FALSE)
                set_state(START_STATE);
        if ((get_attitude(ME) >= 10) && (get_flag(0,14) > 1)) {
                reset_dialog();
                add_dialog_str(0,"Cerund makes certain hand motions, and you suddenly feel disoriented. You recover after a moment, but your knowledge of how to protect yourself from Ball Lightning is gone.",0);
                set_flag(0,14,1);
                run_dialog(1);
        }

        if ((get_ran(1,1,100) < 21) && (get_target() >= 0) && (dist_to_char(get_target()) < 5) && (get_energy(ME) >= 50)) {
                print_named_str(ME,"casts Ball Lightning!");
                put_straight_zap(char_loc_x(ME), char_loc_y(ME),char_loc_x(get_target()),char_loc_y(get_target()),0);
                put_boom_on_char(get_target(),1,0);
                run_animation_sound(102);
                damage_char(get_target(),500 + (get_ran(1,0,300)),3);
                change_char_energy(ME, -50);
                deduct_ap(5);
                if (get_flag(0,14) == 0) {
                        set_flag(0,14,1);
                }
        }
        else {
                do_attack_tactic(2);
        }
break;

beginstate TALKING_STATE;
        if (get_flag(0,16) == 2) {
                print_str("Talking: Cerund is too busy to talk now.");
                end();
        }
        begin_talk_mode(get_memory_cell(3));
break;