// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//Additional cell: 4 if scorpion in southern beach

begincreaturescript;

variables;

short i,target,abil;
short last_abil_time;
short r1;
short my_abil;

body;

beginstate INIT_STATE;
        break;

beginstate DEAD_STATE;
        if (get_memory_cell(4) > 0) {
                inc_flag(0,17,1);
                if (get_flag(0,17) == 9) {
                        print_str_color("With a loud squeal, the last of the scorpions dies.",0);
                        print_str_color("The attack on the beach is now over.",0);
                        set_flag(0,16,3);
                }
        }
break;

beginstate START_STATE;
        if (get_memory_cell(4) > 0 && get_target() < 0) {
                approach_waypoint(ME,0,4);
        }

        // if I have a target for some reason, go attack it
        if (target_ok()) {
                if ((dist_to_char(get_target()) <= 16) && (get_memory_cell(4) == 0)) {
                        set_state(3);
                        set_mobility(ME,1);
                }
                        else set_target(ME,-1);
                }
        
        // Look for a target, attack it if visible
        if (select_target(ME,8,0)) {
                do_attack();
                set_state(3);
                }
                
        // Have I been hit? Strike back!
        if (who_hit_me() >= 0) {
                set_target(ME,who_hit_me());
                do_attack();
                set_state(3);
                }
                
        // Otherwise, just peacefully move around. Go back to start, if I'm too far
        // from where I started.
        if (my_dist_from_start() >= 6 || my_dist_from_start() > 0) {
                if (get_ran(1,1,100) < 40) 
                        return_to_start(ME,1);
                }
                else if (get_memory_cell(0) == 0) {
                        fidget(ME,25);
                        }

        // if we're in combat and the above didn't give me anything to do, just
        // stop now. Otherwise, game will keep running script, and that eats up CPU time.
        if (am_i_doing_action() == FALSE)
                end_combat_turn();
break;

beginstate 3; // attacking
        if (target_ok() == FALSE)
                set_state(START_STATE);
        my_abil = (get_ran(1,1,5));
        if (my_abil == 1 && get_char_status(ME,1) < 1 && my_ap() >= 2) {
                set_char_status(ME,1,10,1,0);
                print_named_str(ME,"blesses itself.");
                deduct_ap(2);
        }
        if (my_abil == 2 && get_char_status(ME,3) < 1 && my_ap() >= 2) {
                set_char_status(ME,3,10,1,0);
                print_named_str(ME,"hastes itself.");
                deduct_ap(2);
        }
        do_attack();
break;

beginstate TALKING_STATE;
        print_str("Talking: It doesn't respond.");
        end();
break;