// martha.txt
// The script for Martha, from Warp.
// Functionally identical to basicnpc, aside from custom dialogue.

begincreaturescript;

variables;

short i,target;
short pc_counter;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
		
	//Okay, first off, why are you killing me? Seriously.
	
	//But really, now it's time for an insta-kill. You deserve it.
	
	reset_dialog();
	add_dialog_str(0,"As you strike what looks to be the killing blow, Martha staggers. She reaches into her robe and produces a glass vial, swiftly drinking the contents.",0);
	add_dialog_str(1,"You see her eyes glow red, and a faint aura of energy appears around her.",0);
	add_dialog_str(2,"_Fools! Did you really think you could beat me in my own lab? This brew may be experimental, but it's good enough for now!_",15);
	add_dialog_str(3,"With that, she makes a few forceful hand motions, and utters a few nonsense syllables. The last thing you see is a bright flash of purple light.",0);
	run_dialog(1);
	
	play_sound(56); //swallow
	play_sound(62); //long zap
	set_character_pose(ME,1);
	force_instant_terrain_redraw();
	pause(2);
	pc_counter = 0;
	while(pc_counter < 4) {
		if(char_ok(pc_counter) == 1) {
			put_jagged_zap(my_loc_x(), my_loc_y(), char_loc_x(pc_counter), char_loc_y(pc_counter), 3);
			put_boom_on_char(pc_counter,6,0);
			}
		pc_counter = pc_counter + 1;
		}
	run_animation_sound(43); //stoning
	kill_char(1000,3,0); //insta-kill
	
	//There, are you happy now?
	
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;