// youngeth.txt
// The script for Young Ethalia, from Warp.
// Functionally identical to basicnpc, aside from custom dialogue.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);

	//Okay, first off, why are you killing me? Seriously.
	
	//But really, now it's time for an insta-kill. You deserve it.
	
	reset_dialog();
	add_dialog_str(0,"You strike what looks to be a killing blow, and the young Ethalia crumples to the ground. For just a second, you pause to consider the ramifications of what you've done.",0);
	add_dialog_str(1,"The whole point of the exercise was to avoid a paradox. And by killing the young Ethalia, you've prevented the older Ethalia from making the portal to go back and stop herself.",0);
	add_dialog_str(2,"Of course, then the portal never existed, and there's no way for you to be here. But then there's no way that you could've possibly killed Ethalia.",0);
	add_dialog_str(3,"It's right about then that everything goes black. Your last thought runs something to the effect of _whoops._",0);
	run_dialog(1);
	
	//look at the blackness
	force_view_center(0,0);
	force_instant_terrain_redraw();
	pause(1);

	kill_char(1000,3,0); //insta-kill
	
	//There, are you happy now?

break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;