// t3thralni.txt
// version 1.0.3
// by Thralni

// A very simple, naive script. Creature attacks anything nearby it hates.
// Once it has won, it returns to its home. WARNING: this script ALWAYS uses flag 270,0. if
// this is a problem, you can change it, but preferably not.

// You can change the name of this script and all "Emperor" or "Thralni" references to
// names and/or words that belong to your scenario. HOWEVER: Include in the readme file
// what the name of the RENAMED script is, and mention with it that its a slightly altered
// version of "t3thralni.txt" made by Thralni.

// version history:

// 1.0.0: Additional release
// 1.0.1: Corrected some mistakes in the automatic talking option (the main feature of this script)
// 1.0.2: Corrected some spelling mistakes and changed some of the descriptions to let it fit with my own scenario.
// 1.0.3: Added clearer instructions about what to do if you want to alter this script in any way.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 4 - distance of the group to the creature using this script, before talk mode is activated. If 0, ignored
//	 Cell 5 - if 1, this creature will teleport away from the party upon being dead.
//	 Cell 6 - here you can configure an item that is given upon death of the character
//	   using this script.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
	
	if (get_memory_cell(5) == 1) {
			message_dialog("You strike the Emperor with your last strength. You hit him, and he falls, but not for long. A big cloud forms around Thralni, and he vanishes. All that is left is a small note.","You quickly pocket it");
			put_boom_on_char(ME,2,0);
			run_animation_sound(10);
			char_give_item(0,get_memory_cell(6));
			
			erase_char(ME);
			end();
			}
break;

beginstate START_STATE; 
	// If party comes close, start talking (memory cell 4 is not 0)
	if (get_flag(270,0) == 0) {
			if (get_memory_cell(4) > 0) {
					if (dist_to_party() == get_memory_cell(4)) {
							set_flag(270,0,1);
							begin_talk_mode(get_memory_cell(3));
							}
					}
			}

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
			print_str("Talking: Thralni doesn't respond.");
			end();
			}
		begin_talk_mode(get_memory_cell(3));
break;